// 2026 Богданович Давид Когут Прихожденко

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія__підлога(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    змінна задіяне_значення = НЕДІЙСНЕ;
    змінна знайдено_задіяне_значення = ні;

    знайдено_задіяне_значення = знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._значення, задіяне_значення::адреса);

    якщо не знайдено_задіяне_значення {
      вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"значення\" має бути числом."));
    }

    якщо задіяне_значення.вид != ЗЧисло {
      вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"значення\" має бути числом."));
    }

    вернути ЧИСЛО(мат_підлога(задіяне_значення.дані як р64));
  }

  дія записати_дію__мат__підлога(
    М: *Машина,
    предмет_модуля: *ПредметМодуля
  ) {
    змінна кількість_параметрів = природне(1);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      НЕДІЙСНЕ
    ));

    змінна д = створити_рідну_дію(
      М,
      М.константи_назв._підлога,
      створити_послідовність_без_копіювання(
        М,
        кількість_параметрів,
        дані_параметрів
      ),
      пусто,
      рідна_дія__підлога,
      пусто
    );

    записати_властивість_модуля(
      М,
      предмет_модуля,
      М.константи_назв._підлога,
      ПРЕДМЕТ(д)
    );
  }
}