// 2026 Богданович Давид Когут Прихожденко

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_структури_Число__є_невизначеністю(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    змінна задіяні = діяльність.задіяні;

    змінна задіяне_значення = НЕДІЙСНЕ;
    змінна знайдено_задіяне_значення = ні;

    знайдено_задіяне_значення = знайти_задіяне(М, задіяні, 0, М.константи_назв._значення, задіяне_значення::адреса);

    якщо не знайдено_задіяне_значення {
      вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"значення\" має бути числом."));
    }

    якщо задіяне_значення.вид != ЗЧисло {
      вернути НЕДІЙСНЕ;
    }

    змінна ч = задіяне_значення.дані як р64;

    вернути ЛОГЛОГ(ч != ч);
  }

  дія записати_дію_класу_Число__є_невизначеністю(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._є_невизначеністю,
      М.пуста_послідовність,
      пусто,
      рідна_дія_структури_Число__є_невизначеністю,
      пусто
    );

    клас_змінити_властивість(
      М,
      М.клас_Число,
      М.константи_назв._є_невизначеністю,
      ПРЕДМЕТ(предмет_дії),
      Місцезнаходження { пусто, 0 }
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"є_невизначеністю\" для структури \"Число\".");
    }
  }
}