// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Список__зріз(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"зріз\"."));
    }

    змінна предмет_списку = діяльність.здійснювач.дані як *Предмет як *ПредметСписку;

    якщо предмет_списку.клас != М.клас_Список {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"зріз\"."));
    }

    змінна задіяне_від = НЕДІЙСНЕ;
    змінна знайдено_задіяне_від = ні;
    змінна задіяне_до = НЕДІЙСНЕ;
    змінна знайдено_задіяне_до = ні;

    знайдено_задіяне_від = знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._від, задіяне_від::адреса);
    знайдено_задіяне_до = знайти_задіяне(М, діяльність.задіяні, 1, М.константи_назв._до, задіяне_до::адреса);

    змінна від = природне(0);
    змінна до = предмет_списку.розмір;

    якщо знайдено_задіяне_від {
      якщо задіяне_від.вид == ЗЧисло {
        змінна з = задіяне_від.дані як р64;

        якщо з < 0 {
          з = 0;
        }

        від = природне(з);
      }
    }
    якщо знайдено_задіяне_до {
      якщо задіяне_до.вид == ЗЧисло {
        змінна з = задіяне_до.дані як р64;

        якщо з < 0 {
          з = 0;
        }

        до = природне(з);
      }
    }

    якщо від == до {
      вернути ПРЕДМЕТ(створити_список(М, 0));
    }

    якщо від > до {
      вернути ПРЕДМЕТ(створити_список(М, 0));
    }

    якщо від >= предмет_списку.розмір {
      вернути ПРЕДМЕТ(створити_список(М, 0));
    }

    якщо до > предмет_списку.розмір {
      до = предмет_списку.розмір;
    }

    змінна розмір_кд = до - від;
    змінна новий_список = створити_список(М, розмір_кд);

    змінна п: природне = 0;
    поки п < розмір_кд {
      записати_в_список(
        М,
        новий_список,
        п,
        предмет_списку.елементи[від + п]
      );

      п += 1;
    }

    вернути ПРЕДМЕТ(новий_список);
  }

  дія записати_метод_класу_Список__зріз(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._зріз,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Список__зріз,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Список,
      М.константи_назв._зріз,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"зріз\" для структури \"Список\".");
    }
  }
}