// 2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Послідовність__перетворити(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"перетворити\"."));
    }

    змінна предмет_послідовності = діяльність.здійснювач.дані як *Предмет як *ПредметПослідовності;

    якщо предмет_послідовності.клас != М.клас_Послідовність {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"перетворити\"."));
    }

    змінна задіяне_дія_перетворення = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._дія_перетворення, задіяне_дія_перетворення::адреса);

    змінна елементи = виділити<Значення>(М, предмет_послідовності.розмір);

    змінна п: природне = 0;

    поки п < предмет_послідовності.розмір {
      змінна поточне_значення = предмет_послідовності.елементи[п];

      змінна задіяні = Задіяні { ВидЗадіяних2, 3, виділити<Значення>(М, 3), 0 };
      задіяні.дані[0] = поточне_значення;
      задіяні.дані[1] = ЧИСЛО(р64(п));
      задіяні.дані[2] = ПРЕДМЕТ(предмет_послідовності);

      змінна результат_здійснення = здійснити(
        М,
        НЕДІЙСНЕ,
        задіяне_дія_перетворення,
        задіяні,
        Місцезнаходження { пусто, 0 }
      );

      якщо М.стан_падіння {
        звільнити(М, елементи);

        вернути НЕДІЙСНЕ;
      }

      елементи[п] = результат_здійснення;

      п += 1;
    }

    вернути ПРЕДМЕТ(створити_послідовність_без_копіювання(
      М,
      предмет_послідовності.розмір,
      елементи
    ));
  }

  дія записати_метод_класу_Послідовність__перетворити(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._перетворити,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Послідовність__перетворити,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Послідовність,
      М.константи_назв._перетворити,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"перетворити\" для структури \"Послідовність\".");
    }
  }
}