// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  дія записати_метод_класу_Модуль__чародія_текст(М: *Машина);
  дія записати_дію_класу_Модуль__отримати_назву(М: *Машина);

  внутрішня дія записати_ознаки_класу_Модуль(М: *Машина) {
    М.клас_Модуль.ознаки = М.пуста_послідовність;
  }

  дія заповнити_клас_Модуль(
    М: *Машина
  ) {
    М.клас_Модуль.вбудований = так;
    М.клас_Модуль.заборонити_наслідування = так;

    записати_ознаки_класу_Модуль(М);

    записати_метод_класу_Модуль__чародія_текст(М);

    записати_дію_класу_Модуль__отримати_назву(М);
  }

  дія створити_модуль(
    М: *Машина,
    назва: *ПредметТексту
  ) -> *ПредметМодуля {
    змінна предмет = виділити_предмет<ПредметМодуля>(М, М.клас_Модуль);

    предмет.готовий = ні;
    предмет.назва = назва;
    предмет.властивості = Призначення { 0, пусто, 0 };

    вернути предмет;
  }

  внутрішня дія записати_властивості_модуля_з_іменованого(
    М: *Машина,
    задіяні: Задіяні,
    позиція: п32,
    назва: *ПредметТексту,
    значення: Значення,
    аргумент: адреса
  ) {
    якщо порівняти_тексти(М, назва, М.константи_назв._назва) {
      вернути;
    }

    записати_властивість_модуля(
      М,
      аргумент як *ПредметМодуля,
      назва,
      значення
    );
  }

  дія здійснити_клас_модуля(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна задіяне_назва = НЕДІЙСНЕ;

    знайти_задіяне(М, задіяні, 0, М.константи_назв._назва, задіяне_назва::адреса);

    змінна назва: *ПредметТексту = пусто;

    якщо задіяне_назва.вид == ЗНедійсне {
    } інакше якщо задіяне_назва.вид == ЗДійсне або задіяне_назва.вид == ЗЧисло {
      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Назва модуля має бути текстом."), місцезнаходження);
    } інакше {
      назва = задіяне_назва.дані як *Предмет як *ПредметТексту;

      якщо назва.клас != М.клас_Текст {
        вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Назва модуля має бути текстом."), місцезнаходження);
      }
    }

    змінна предмет_модуля = створити_модуль(М, назва);

    перебрати_іменовані_задіяні(
      М,
      задіяні,
      записати_властивості_модуля_з_іменованого,
      предмет_модуля
    );

    вернути ПРЕДМЕТ(предмет_модуля);
  }

  дія записати_властивість_модуля(
    М: *Машина,
    предмет_модуля: *ПредметМодуля,
    назва: *ПредметТексту,
    значення: Значення
  ) {
    призначити(
      М,
      предмет_модуля.властивості::адреса,
      назва,
      значення
    );
  }

  дія предмет_модуля_отримати_властивість(
    М: *Машина,
    предмет_модуля: *ПредметМодуля,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна значення_властивості = НЕДІЙСНЕ;

    якщо знайти_призначене(
      М,
      предмет_модуля.властивості,
      назва,
      значення_властивості::адреса
    ) {
      вернути значення_властивості;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Модуль,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}