// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  дія записати_метод_класу_Клас__чародія_текст(М: *Машина);

  внутрішня дія записати_ознаки_класу_Клас(М: *Машина) {
    змінна кількість_ознак = природне(3);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._назва,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[1] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._предок,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[2] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._ознаки,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_Клас.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  внутрішня дія записати_властивість_класу_Клас__Ознака(М: *Машина) {
    клас_змінити_властивість(
      М,
      М.клас_Клас,
      М.константи_назв._Ознака,
      ПРЕДМЕТ(М.клас_Ознака),
      Місцезнаходження { пусто, 0 }
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі властивості \"Ознака\" для класу \"Клас\".");
    }
  }

  дія заповнити_клас_Клас(
    М: *Машина
  ) {
    М.клас_Клас.вбудований = так;
    М.клас_Клас.заборонити_наслідування = так;

    записати_ознаки_класу_Клас(М);

    записати_метод_класу_Клас__чародія_текст(М);

    записати_властивість_класу_Клас__Ознака(М);
  }

  дія створити_клас(
    М: *Машина,
    назва: *ПредметТексту,
    ознаки: *ПредметПослідовності
  ) -> *ПредметКласу {
    змінна предмет = виділити_предмет<ПредметКласу>(М, М.клас_Клас);

    предмет.вбудований = ні;
    предмет.заборонити_наслідування = ні;
    предмет.назва = назва;
    предмет.ознаки = ознаки;
    предмет.методи = Методи { 0, пусто };
    предмет.властивості = Призначення { 0, пусто, 0 };

    вернути предмет;
  }

  дія змінити_властивість_класу(
    М: *Машина,
    предмет_класу: *ПредметКласу,
    назва: *ПредметТексту,
    значення: Значення,
  ) {
    призначити(
      М,
      предмет_класу.властивості::адреса,
      назва,
      значення
    );
  }

  // позначка: прохід по типах предметів
  дія клас_здійснити(
    М: *Машина,
    предмет_класу: *ПредметКласу,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо предмет_класу.вбудований {
      якщо предмет_класу == М.клас_Модуль {
        вернути здійснити_клас_модуля(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Параметр {
        вернути здійснити_клас_параметра(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Ознака {
        вернути здійснити_клас_ознаки(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Число {
        вернути здійснити_клас_числа(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Текст {
        вернути здійснити_клас_тексту(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Дія {
        вернути здійснити_клас_дії(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Список {
        вернути здійснити_клас_списку(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Словник {
        вернути здійснити_клас_словника(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Дані {
        вернути здійснити_клас_даних(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПроміжокЧисел {
        вернути здійснити_клас_проміжка_чисел(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірПроміжкаЧисел {
        вернути здійснити_клас_перебору_проміжка_чисел(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірДаних {
        вернути здійснити_клас_перебору_даних(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірПослідовності {
        вернути здійснити_клас_перебору_послідовності(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірСловника {
        вернути здійснити_клас_перебору_словника(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірСписку {
        вернути здійснити_клас_перебору_списку(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірТексту {
        вернути здійснити_клас_перебору_тексту(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Послідовність {
        вернути здійснити_клас_послідовності(М, задіяні, місцезнаходження);
      }

      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас."), місцезнаходження);
    }

    змінна предмет = створити_складений_предмет(М, предмет_класу);

    змінна предмет_метода = знайти_метод_в_класі(
      М,
      предмет_класу,
      М.константи_назв._чародія
    );

    якщо предмет_метода != пусто {
      предмет_дії_здійснити(
        М,
        ПРЕДМЕТ(предмет),
        предмет_метода,
        задіяні,
        місцезнаходження
      );

      вернути ПРЕДМЕТ(предмет);
    }

    покласти_в_історію_здійснення(
      М,
      пусто,
      ПРЕДМЕТ(предмет),
      пусто,
      задіяні,
      місцезнаходження
    );

    змінна розмір_позиційних = задіяні.розмір - (задіяні.кількість_імен * 2);

    якщо предмет_класу.ознаки.розмір > 0 {
      змінна п: п32 = 0;

      поки п < п32(предмет_класу.ознаки.розмір) {
        змінна ознака = предмет_класу.ознаки.елементи[п].дані як *Предмет як *ПредметОзнаки;

        якщо п < розмір_позиційних {
          призначити(
            М,
            предмет.властивості::адреса,
            ознака.назва,
            задіяні.дані[п]
          );
        } інакше {
          призначити(
            М,
            предмет.властивості::адреса,
            ознака.назва,
            ознака.значення
          );
        }

        п += 1;
      }

      якщо задіяні.кількість_імен > 0 {
        п = 0;

        поки п < задіяні.кількість_імен {
          змінна назва = задіяні.дані[розмір_позиційних + задіяні.кількість_імен + п].дані як *Предмет як *ПредметТексту;
          змінна значення = задіяні.дані[розмір_позиційних + п];

          призначити(
            М,
            предмет.властивості::адреса,
            назва,
            значення
          );

          п += 1;
        }
      }
    }

    видалити_з_історії_здійснення(М, 1);

    вернути ПРЕДМЕТ(предмет);
  }

  дія записати_метод_класу(
    М: *Машина,
    предмет_класу: *ПредметКласу,
    назва: *ПредметТексту,
    значення_дії: *ПредметДії
  ) {
    змінна п: природне = 0;

    поки п < предмет_класу.методи.розмір {
      змінна метод = предмет_класу.методи.дані[п]::адреса;

      якщо порівняти_тексти(М, метод.назва, назва) {
        метод.значення = значення_дії;

        вернути;
      }

      п += 1;
    }

    предмет_класу.методи.дані = перевиділити<Метод>(М, предмет_класу.методи.дані, предмет_класу.методи.розмір + 1);
    предмет_класу.методи.дані[предмет_класу.методи.розмір] = Метод { назва, значення_дії };
    предмет_класу.методи.розмір += 1;
  }

  дія знайти_метод_в_класі(
    М: *Машина,
    предмет_класу: *ПредметКласу,
    назва: *ПредметТексту
  ) -> *ПредметДії {
    змінна п: природне = 0;

    поки п < предмет_класу.методи.розмір {
      змінна метод = предмет_класу.методи.дані[п];

      якщо порівняти_тексти(М, метод.назва, назва) {
        вернути метод.значення;
      }

      п += 1;
    }

    вернути пусто;
  }

  дія клас_отримати_властивість(
    М: *Машина,
    предмет_класу: *ПредметКласу,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо порівняти_тексти(М, назва, М.константи_назв._назва) {
      якщо предмет_класу.назва == пусто {
        вернути НЕДІЙСНЕ;
      }
      вернути ПРЕДМЕТ(предмет_класу.назва);
    }
    якщо порівняти_тексти(М, назва, М.константи_назв._ознаки) {
      вернути ПРЕДМЕТ(предмет_класу.ознаки);
    }

    змінна значення_властивості = НЕДІЙСНЕ;

    якщо знайти_призначене(
      М,
      предмет_класу.властивості,
      назва,
      значення_властивості::адреса
    ) {
      вернути значення_властивості;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Клас,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія клас_змінити_властивість(
    М: *Машина,
    предмет_класу: *ПредметКласу,
    назва: *ПредметТексту,
    значення: Значення,
    місцезнаходження: Місцезнаходження
  ) {
    якщо порівняти_тексти(М, назва, М.константи_назв._назва) {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо змінити назву структури."), місцезнаходження);
      вернути;
    }
    якщо порівняти_тексти(М, назва, М.константи_назв._ознаки) {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо змінити ознаки структури."), місцезнаходження);
      вернути;
    }

    змінити_властивість_класу(
      М,
      предмет_класу,
      назва,
      значення
    );
  }
}