// 2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Текст__зріз(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію тексту \"зріз\"."));
    }

    змінна предмет_тексту = діяльність.здійснювач.дані як *Предмет як *ПредметТексту;

    якщо предмет_тексту.клас != М.клас_Текст {
      вернути ПАДІННЯ(М, створити_текст(М, "Дію \"зріз\" можна застосувати лише до тексту."));
    }

    змінна задіяне_від = НЕДІЙСНЕ;
    змінна знайдено_задіяне_від = ні;
    змінна задіяне_до = НЕДІЙСНЕ;
    змінна знайдено_задіяне_до = ні;

    знайдено_задіяне_від = знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._від, задіяне_від::адреса);
    знайдено_задіяне_до = знайти_задіяне(М, діяльність.задіяні, 1, М.константи_назв._до, задіяне_до::адреса);

    змінна від = природне(0);
    змінна до = предмет_тексту.значення.розмір;

    якщо знайдено_задіяне_від {
      якщо задіяне_від.вид == ЗЧисло {
        змінна з = задіяне_від.дані як р64;

        якщо з < 0 {
          з = 0;
        }

        від = природне(з);
      }
    }
    якщо знайдено_задіяне_до {
      якщо задіяне_до.вид == ЗЧисло {
        змінна з = задіяне_до.дані як р64;

        якщо з < 0 {
          з = 0;
        }

        до = природне(з);
      }
    }

    якщо від == до {
      вернути ПРЕДМЕТ(створити_текст(М, ""));
    }

    якщо від > до {
      вернути ПРЕДМЕТ(створити_текст(М, ""));
    }

    якщо від >= предмет_тексту.значення.розмір {
      вернути ПРЕДМЕТ(створити_текст(М, ""));
    }

    якщо до > предмет_тексту.значення.розмір {
      до = предмет_тексту.значення.розмір;
    }

    змінна розмір_кд = до - від;
    змінна нові_дані = виділити<п8>(М, розмір_кд);

    змінна п: природне = 0;
    поки п < розмір_кд {
      нові_дані[п] = предмет_тексту.значення.дані[від + п];

      п += 1;
    }

    вернути ПРЕДМЕТ(створити_текст_без_копіювання(
      М,
      розмір_кд,
      нові_дані
    ));
  }

  дія записати_метод_класу_Текст__зріз(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._зріз,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Текст__зріз,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Текст,
      М.константи_назв._зріз,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"зріз\" для структури \"Текст\".");
    }
  }
}