// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  дія записати_метод_класу_Текст__чародія_число(М: *Машина);
  дія записати_метод_класу_Текст__чародія_текст(М: *Машина);
  дія записати_метод_класу_Текст__чародія_перебір(М: *Машина);
  дія записати_метод_класу_Текст__зріз(М: *Машина);

  внутрішня дія записати_ознаки_класу_Текст(М: *Машина) {
    змінна кількість_ознак = природне(1);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._довжина,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_Текст.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  дія заповнити_клас_Текст(
    М: *Машина
  ) {
    М.клас_Текст.вбудований = так;
    М.клас_Текст.заборонити_наслідування = так;

    записати_ознаки_класу_Текст(М);

    записати_метод_класу_Текст__чародія_число(М);
    записати_метод_класу_Текст__чародія_текст(М);
    записати_метод_класу_Текст__чародія_перебір(М);
    записати_метод_класу_Текст__зріз(М);
  }

  дія створити_текст(
    М: *Машина,
    значення: кд
  ) -> *ПредметТексту {
    змінна предмет = виділити_предмет<ПредметТексту>(М, М.клас_Текст);

    змінна копія_тексту = виділити<п8>(М, значення.розмір);

    змінна п: природне = 0;
    поки п < значення.розмір {
      копія_тексту[п] = значення.дані[п];

      п += 1;
    }

    предмет.значення = кд { копія_тексту, значення.розмір };

    вернути предмет;
  }

  дія створити_текст_без_копіювання(
    М: *Машина,
    розмір: природне,
    дані: *п8
  ) -> *ПредметТексту {
    змінна предмет = виділити_предмет<ПредметТексту>(М, М.клас_Текст);

    предмет.значення = кд { дані, розмір };

    вернути предмет;
  }

  дія здійснити_клас_тексту(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна задіяне_значення = НЕДІЙСНЕ;

    знайти_задіяне(М, задіяні, 0, М.константи_назв._значення, задіяне_значення::адреса);

    змінна предмет_тексту = отримати_текст(
      М,
      задіяне_значення,
      Місцезнаходження { пусто, 0 }
    );

    якщо М.стан_падіння {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_тексту);
  }

  дія предмет_тексту_отримати_властивість(
    М: *Машина,
    предмет_тексту: *ПредметТексту,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо порівняти_тексти(М, назва, М.константи_назв._довжина) {
      вернути ЧИСЛО(р64(предмет_тексту.значення.розмір));
    }

    якщо порівняти_тексти(М, назва, М.константи_назв._розмір) {
      надрукувати_кд(М, "УВАГА: ознаку \"розмір\" змінено на \"довжина\" і в подальшому буде видалено");
      вернути ЧИСЛО(р64(предмет_тексту.значення.розмір));
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Текст,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_тексту_отримати_елемент(
    М: *Машина,
    предмет_тексту: *ПредметТексту,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо ключ.вид == ЗЧисло {
      змінна позиція = природне(ключ.дані як р64);

      якщо позиція >= 0 і позиція < предмет_тексту.значення.розмір {
        вернути ЧИСЛО(р64(предмет_тексту.значення.дані[позиція]));
      }
    }

    вернути НЕДІЙСНЕ;
  }
}