// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  дія записати_метод_класу_ПроміжокЧисел__чародія_текст(М: *Машина);
  дія записати_метод_класу_ПроміжокЧисел__чародія_перебір(М: *Машина);

  внутрішня дія записати_властивість_класу_ПроміжокЧисел__Перебір(М: *Машина) {
    клас_змінити_властивість(
      М,
      М.клас_ПроміжокЧисел,
      М.константи_назв._Перебір,
      ПРЕДМЕТ(М.клас_ПеребірПроміжкаЧисел),
      Місцезнаходження { пусто, 0 }
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі властивості \"Перебір\" для структури \"ПроміжокЧисел\".");
    }
  }

  внутрішня дія записати_ознаки_класу_ПроміжокЧисел(М: *Машина) {
    змінна кількість_ознак = природне(3);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._від,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[1] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._до,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[2] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._включно,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_ПроміжокЧисел.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  дія заповнити_клас_ПроміжокЧисел(
    М: *Машина
  ) {
    М.клас_ПроміжокЧисел.вбудований = так;
    М.клас_ПроміжокЧисел.заборонити_наслідування = так;

    записати_ознаки_класу_ПроміжокЧисел(М);

    записати_метод_класу_ПроміжокЧисел__чародія_текст(М);
    записати_метод_класу_ПроміжокЧисел__чародія_перебір(М);

    записати_властивість_класу_ПроміжокЧисел__Перебір(М);
  }

  дія створити_проміжок_чисел(
    М: *Машина,
    від: р64,
    до: р64,
    включно: логічне
  ) -> *ПредметПроміжкаЧисел {
    змінна предмет = виділити_предмет<ПредметПроміжкаЧисел>(М, М.клас_ПроміжокЧисел);

    предмет.від = від;
    предмет.до = до;
    предмет.включно = включно;

    вернути предмет;
  }

  дія здійснити_клас_проміжка_чисел(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна задіяне_від = НЕДІЙСНЕ;
    змінна задіяне_до = НЕДІЙСНЕ;
    змінна задіяне_включно = НЕДІЙСНЕ;

    знайти_задіяне(М, задіяні, 0, М.константи_назв._від, задіяне_від::адреса);
    знайти_задіяне(М, задіяні, 1, М.константи_назв._до, задіяне_до::адреса);
    знайти_задіяне(М, задіяні, 2, М.константи_назв._включно, задіяне_включно::адреса);

    змінна від = р64(0.0);
    змінна до = р64(0.0);
    змінна включно = задіяне_включно.вид != ЗНедійсне;

    якщо задіяне_від.вид == ЗЧисло {
      від = задіяне_від.дані як р64;
    } інакше {
      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Задіяне \"від\" має бути числом."), місцезнаходження);
    }
    якщо задіяне_до.вид == ЗЧисло {
      до = задіяне_до.дані як р64;
    } інакше {
      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Задіяне \"до\" має бути числом."), місцезнаходження);
    }

    вернути ПРЕДМЕТ(створити_проміжок_чисел(
      М,
      від,
      до,
      включно
    ));
  }

  дія предмет_проміжка_чисел_отримати_властивість(
    М: *Машина,
    предмет_проміжка_чисел: *ПредметПроміжкаЧисел,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо порівняти_тексти(М, назва, М.константи_назв._від) {
      вернути ЧИСЛО(предмет_проміжка_чисел.від);
    }
    якщо порівняти_тексти(М, назва, М.константи_назв._до) {
      вернути ЧИСЛО(предмет_проміжка_чисел.до);
    }
    якщо порівняти_тексти(М, назва, М.константи_назв._включно) {
      вернути ЛОГЛОГ(предмет_проміжка_чисел.включно);
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПроміжокЧисел,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}