// 2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Послідовність__позиція(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"позиція\"."));
    }

    змінна предмет_послідовності = діяльність.здійснювач.дані як *Предмет як *ПредметПослідовності;

    якщо предмет_послідовності.клас != М.клас_Послідовність {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"позиція\"."));
    }

    змінна задіяне_значення = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._значення, задіяне_значення::адреса);

    змінна п: природне = 0;

    поки п < предмет_послідовності.розмір {
      якщо порівняти_значення(М, предмет_послідовності.елементи[п], задіяне_значення) {
        вернути ЧИСЛО(р64(п));
      }

      п += 1;
    }

    вернути ЧИСЛО(р64(0)-1);
  }

  дія записати_метод_класу_Послідовність__позиція(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._позиція,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Послідовність__позиція,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Послідовність,
      М.константи_назв._позиція,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі методу \"позиція\" для структури \"Послідовність\".");
    }
  }
}