// 2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Послідовність__зріз(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"зріз\"."));
    }

    змінна предмет_послідовності = діяльність.здійснювач.дані як *Предмет як *ПредметПослідовності;

    якщо предмет_послідовності.клас != М.клас_Послідовність {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"зріз\"."));
    }

    змінна задіяне_від = НЕДІЙСНЕ;
    змінна знайдено_задіяне_від = ні;
    змінна задіяне_до = НЕДІЙСНЕ;
    змінна знайдено_задіяне_до = ні;

    знайдено_задіяне_від = знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._від, задіяне_від::адреса);
    знайдено_задіяне_до = знайти_задіяне(М, діяльність.задіяні, 1, М.константи_назв._до, задіяне_до::адреса);

    змінна від = природне(0);
    змінна до = предмет_послідовності.розмір;

    якщо знайдено_задіяне_від {
      якщо задіяне_від.вид == ЗЧисло {
        змінна з = задіяне_від.дані як р64;

        якщо з < 0 {
          з = 0;
        }

        від = природне(з);
      }
    }
    якщо знайдено_задіяне_до {
      якщо задіяне_до.вид == ЗЧисло {
        змінна з = задіяне_до.дані як р64;

        якщо з < 0 {
          з = 0;
        }

        до = природне(з);
      }
    }

    якщо від == до {
      вернути ПРЕДМЕТ(М.пуста_послідовність);
    }

    якщо від > до {
      вернути ПРЕДМЕТ(М.пуста_послідовність);
    }

    якщо від >= предмет_послідовності.розмір {
      вернути ПРЕДМЕТ(М.пуста_послідовність);
    }

    якщо до > предмет_послідовності.розмір {
      до = предмет_послідовності.розмір;
    }

    змінна новий_розмір = до - від;
    змінна нові_елементи = виділити<Значення>(М, новий_розмір);

    змінна п: природне = 0;
    поки п < новий_розмір {
      нові_елементи[п] = предмет_послідовності.елементи[від + п];

      п += 1;
    }

    вернути ПРЕДМЕТ(створити_послідовність_без_копіювання(
      М,
      новий_розмір,
      нові_елементи
    ));
  }

  дія записати_метод_класу_Послідовність__зріз(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._зріз,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Послідовність__зріз,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Послідовність,
      М.константи_назв._зріз,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"зріз\" для структури \"Послідовність\".");
    }
  }
}