// 2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Послідовність__відібрати(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"відібрати\"."));
    }

    змінна предмет_послідовності = діяльність.здійснювач.дані як *Предмет як *ПредметПослідовності;

    якщо предмет_послідовності.клас != М.клас_Послідовність {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію послідовності \"відібрати\"."));
    }

    змінна задіяне_дія_перевірки = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._дія_перевірки, задіяне_дія_перевірки::адреса);

    змінна елементи = зробити_накопичувач<Значення>(М, 0);
    змінна п: природне = 0;

    поки п < предмет_послідовності.розмір {
      змінна поточне_значення = предмет_послідовності.елементи[п];

      змінна задіяні = Задіяні { ВидЗадіяних2, 3, виділити<Значення>(М, 3), 0 };
      задіяні.дані[0] = поточне_значення;
      задіяні.дані[1] = ЧИСЛО(р64(п));
      задіяні.дані[2] = ПРЕДМЕТ(предмет_послідовності);

      змінна результат_здійснення = здійснити(
        М,
        НЕДІЙСНЕ,
        задіяне_дія_перевірки,
        задіяні,
        Місцезнаходження { пусто, 0 }
      );

      якщо М.стан_падіння {
        елементи.звільнити_дані(М);

        вернути НЕДІЙСНЕ;
      }

      якщо результат_здійснення.вид != ЗНедійсне {
        елементи.покласти(М, поточне_значення);
      }

      п += 1;
    }

    вернути ПРЕДМЕТ(створити_послідовність_без_копіювання(
      М,
      елементи.розмір,
      елементи.дані
    ));
  }

  дія записати_метод_класу_Послідовність__відібрати(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._відібрати,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Послідовність__відібрати,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Послідовність,
      М.константи_назв._відібрати,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"відібрати\" для структури \"Послідовність\".");
    }
  }
}