// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_метода_структури_ПеребірТексту__далі(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору тексту \"далі\"."));
    }

    змінна предмет_перебору_тексту = діяльність.здійснювач.дані як *Предмет як *ПредметПереборуТексту;

    якщо предмет_перебору_тексту.клас != М.клас_ПеребірТексту {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору тексту \"далі\"."));
    }

    якщо предмет_перебору_тексту.почато {
      предмет_перебору_тексту.позиція += 1;
    } інакше {
      предмет_перебору_тексту.позиція = 0;
      предмет_перебору_тексту.почато = так;
    }

    якщо предмет_перебору_тексту.позиція < предмет_перебору_тексту.предмет_тексту.значення.розмір {
      предмет_перебору_тексту.поточне_значення = р64(предмет_перебору_тексту.предмет_тексту.значення.дані[предмет_перебору_тексту.позиція]);

      вернути ДІЙСНЕ;
    }

    вернути НЕДІЙСНЕ;
  }

  дія записати_метод_класу_ПеребірТексту__далі(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._далі,
      М.пуста_послідовність,
      пусто,
      рідна_дія_метода_структури_ПеребірТексту__далі,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_ПеребірТексту,
      М.константи_назв._далі,
      предмет_дії
    );
  }
}