// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Список__позиція(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"позиція\"."));
    }

    змінна предмет_списку = діяльність.здійснювач.дані як *Предмет як *ПредметСписку;

    якщо предмет_списку.клас != М.клас_Список {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"позиція\"."));
    }

    змінна задіяне_значення = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._значення, задіяне_значення::адреса);

    змінна п: природне = 0;

    поки п < предмет_списку.розмір {
      якщо порівняти_значення(М, предмет_списку.елементи[п], задіяне_значення) {
        вернути ЧИСЛО(р64(п));
      }

      п += 1;
    }

    вернути ЧИСЛО(р64(0)-1);
  }

  дія записати_метод_класу_Список__позиція(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._позиція,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Список__позиція,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Список,
      М.константи_назв._позиція,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі методу \"позиція\" для структури \"Список\".");
    }
  }
}