// 2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  дія записати_метод_класу_Ознака__чародія_текст(М: *Машина);

  внутрішня дія записати_ознаки_класу_Ознака(М: *Машина) {
    змінна кількість_ознак = природне(3);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._назва,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[1] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._тип,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[2] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._значення,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_Ознака.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  дія заповнити_клас_Ознака(
    М: *Машина
  ) {
    М.клас_Ознака.вбудований = так;
    М.клас_Ознака.заборонити_наслідування = так;

    записати_ознаки_класу_Ознака(М);

    записати_метод_класу_Ознака__чародія_текст(М);
  }

  дія створити_ознаку(
    М: *Машина,
    назва: *ПредметТексту,
    тип: *Предмет,
    значення: Значення
  ) -> *ПредметОзнаки {
    змінна предмет = виділити_предмет<ПредметОзнаки>(М, М.клас_Ознака);

    предмет.назва = назва;
    предмет.тип = пусто;
    предмет.значення = значення;

    вернути предмет;
  }

  дія здійснити_клас_ознаки(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо створити ознаку вручну."), місцезнаходження);
  }

  дія предмет_ознаки_отримати_властивість(
    М: *Машина,
    предмет_ознаки: *ПредметОзнаки,
    назва: *ПредметТексту, місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо порівняти_тексти(М, назва, М.константи_назв._назва) {
      вернути ПРЕДМЕТ(предмет_ознаки.назва);
    }
    якщо порівняти_тексти(М, назва, М.константи_назв._тип) {
      якщо предмет_ознаки.тип == пусто {
        вернути НЕДІЙСНЕ;
      }
      вернути ПРЕДМЕТ(предмет_ознаки.тип);
    }
    якщо порівняти_тексти(М, назва, М.константи_назв._значення) {
      вернути предмет_ознаки.значення;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Ознака,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}