// 2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/бібліотека;
взяти визначення мавка/пристрій;

простір мавка {
  простір бібліотека {
    внутрішня дія рідна_дія__прочитати(
      М: *Машина,
      діяльність: *Діяльність
    ) -> ЗначенняАбоСтанПадіння {
      змінна задіяне_тип = НЕДІЙСНЕ;
      змінна знайдено_задіяне_тип = ні;
      змінна задіяне_куди = НЕДІЙСНЕ;
      змінна знайдено_задіяне_куди = ні;

      знайдено_задіяне_тип = знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._тип, задіяне_тип::адреса);
      знайдено_задіяне_куди = знайти_задіяне(М, діяльність.задіяні, 1, М.константи_назв._куди, задіяне_куди::адреса);

      якщо не знайдено_задіяне_куди {
        вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"куди\" має бути текстом або даними."));
      }

      змінна як_текст = ні;
      якщо знайдено_задіяне_тип {
        якщо задіяне_тип.вид == ЗПредмет {
          змінна предмет = задіяне_тип.дані як *Предмет;

          якщо предмет == М.клас_Текст {
            як_текст = так;
          } інакше якщо предмет == М.клас_Дані {
            як_текст = ні;
          } інакше {
            вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"тип\" має бути структурою тексту або даних."));
          }
        } інакше {
          вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"тип\" має бути структурою тексту або даних."));
        }
      }

      змінна шлях_ю8 = ю8 { пусто, 0 };

      якщо задіяне_куди.вид == ЗПредмет {
        змінна предмет = задіяне_куди.дані як *Предмет;

        якщо предмет.клас == М.клас_Текст {
          змінна предмет_тексту = предмет як *ПредметТексту;
          змінна позиція_помилки: природне = 0;

          якщо не пристрій_мавки_перекодувати_кд_в_ю8(
            предмет_тексту.значення.розмір,
            предмет_тексту.значення.дані,
            шлях_ю8.розмір::адреса,
            шлях_ю8.дані::адреса,
            позиція_помилки::адреса
          ) {
            вернути ПАДІННЯ(М, створити_текст(М, "Не вдалося перекодувати \"куди\" в юнікод."));
          }
        } інакше якщо предмет.клас == М.клас_Дані {
          змінна предмет_даних = предмет як *ПредметДаних;

          шлях_ю8.розмір = предмет_даних.розмір;
          шлях_ю8.дані = предмет_даних.дані;
        } інакше {
          вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"куди\" має бути текстом або даними."));
        }
      } інакше {
        вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"куди\" має бути текстом або даними."));
      }

      змінна дані_файлу = Дані { 0, пусто };

      якщо не бібліотека_мавки_прочитати_файл(шлях_ю8.дані, шлях_ю8.розмір, дані_файлу::адреса) {
        звільнити(М, шлях_ю8.дані);

        вернути НЕДІЙСНЕ;
      }

      звільнити(М, шлях_ю8.дані);

      якщо як_текст {
        вернути ПРЕДМЕТ(створити_текст_без_копіювання(
          М,
          дані_файлу.розмір,
          дані_файлу.дані
        ));
      }

      вернути ПРЕДМЕТ(створити_дані_без_копіювання(
        М,
        дані_файлу.розмір,
        дані_файлу.дані
      ));
    }

    дія записати_дію__фс__прочитати(
      М: *Машина,
      предмет_модуля: *ПредметМодуля
    ) {
      // потім: створити параметри

      змінна д = створити_рідну_дію(
        М,
        створити_текст(М, "прочитати"),
        М.пуста_послідовність,
        пусто,
        рідна_дія__прочитати,
        пусто
      );

      записати_властивість_модуля(
        М,
        предмет_модуля,
        М.константи_назв._прочитати,
        ПРЕДМЕТ(д)
      );
    }
  }
}