// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка;

простір мавка {
  дія записати_метод_класу_Словник__чародія_текст(М: *Машина);
  дія записати_метод_класу_Словник__чародія_перебір(М: *Машина);
  дія записати_метод_класу_Словник__ключі(М: *Машина);
  дія записати_метод_класу_Словник__значення(М: *Машина);
  дія записати_метод_класу_Словник__містить(М: *Машина);

  внутрішня дія записати_ознаки_класу_Словник(М: *Машина) {
    змінна кількість_ознак = природне(1);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._розмір,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_Словник.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  дія заповнити_клас_Словник(
    М: *Машина
  ) {
    М.клас_Словник.вбудований = так;
    М.клас_Словник.заборонити_наслідування = так;

    записати_ознаки_класу_Словник(М);

    записати_метод_класу_Словник__чародія_текст(М);
    записати_метод_класу_Словник__чародія_перебір(М);
    записати_метод_класу_Словник__ключі(М);
    записати_метод_класу_Словник__значення(М);
    записати_метод_класу_Словник__містить(М);
  }

  дія створити_словник(
    М: *Машина
  ) -> *ПредметСловника {
    змінна предмет = виділити_предмет<ПредметСловника>(М, М.клас_Словник);

    предмет.розмір = 0;
    предмет.елементи = пусто;

    вернути предмет;
  }

  дія записати_в_словник(
    М: *Машина,
    словник: *ПредметСловника,
    ключ: Значення,
    значення: Значення
  ) {
    змінна властивості_словника = словник;

    змінна п: природне = 0;

    поки п < властивості_словника.розмір {
      змінна елемент = властивості_словника.елементи[п]::адреса;

      якщо порівняти_значення(М, елемент.ключ, ключ) {
        елемент.значення = значення;

        вернути;
      }

      п += 1;
    }

    властивості_словника.елементи = перевиділити<ЕлементСловника>(М, властивості_словника.елементи, властивості_словника.розмір + 1);
    властивості_словника.елементи[властивості_словника.розмір] = ЕлементСловника { ключ, значення };
    властивості_словника.розмір += 1;
  }

  дія здійснити_клас_словника(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"Словник\"."), місцезнаходження);
  }

  дія предмет_словника_отримати_властивість(
    М: *Машина,
    предмет_словника: *ПредметСловника,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо порівняти_тексти(М, назва, М.константи_назв._розмір) {
      вернути ЧИСЛО(р64(предмет_словника.розмір));
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Словник,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_словника_отримати_елемент(
    М: *Машина,
    предмет_словника: *ПредметСловника,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна п: природне = 0;

    поки п < предмет_словника.розмір {
      змінна елемент = предмет_словника.елементи[п];

      якщо порівняти_значення(М, елемент.ключ, ключ) {
        вернути елемент.значення;
      }

      п += 1;
    }

    вернути НЕДІЙСНЕ;
  }

  дія предмет_словника_змінити_елемент(
    М: *Машина,
    предмет_словника: *ПредметСловника,
    ключ: Значення,
    значення_елемента: Значення,
    місцезнаходження: Місцезнаходження
  ) -> СтанПадіння {
    змінна п: природне = 0;

    поки п < предмет_словника.розмір {
      змінна елемент = предмет_словника.елементи[п]::адреса;

      якщо порівняти_значення(М, елемент.ключ, ключ) {
        елемент.значення = значення_елемента;

        вернути;
      }

      п += 1;
    }

    предмет_словника.розмір += 1;
    предмет_словника.елементи = перевиділити<ЕлементСловника>(М, предмет_словника.елементи, предмет_словника.розмір);
    предмет_словника.елементи[предмет_словника.розмір - 1] = ЕлементСловника {
      ключ = ключ,
      значення = значення_елемента
    };
  }
}