// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Список__обернути(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"обернути\"."));
    }

    змінна предмет_списку = діяльність.здійснювач.дані як *Предмет як *ПредметСписку;

    якщо предмет_списку.клас != М.клас_Список {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"обернути\"."));
    }

    змінна новий_список = створити_список(М, предмет_списку.розмір);

    змінна п: природне = 0;

    поки п < предмет_списку.розмір {
      записати_в_список(
        М,
        новий_список,
        предмет_списку.розмір - п - 1,
        предмет_списку.елементи[п]
      );

      п += 1;
    }

    вернути ПРЕДМЕТ(новий_список);
  }

  дія записати_метод_класу_Список__обернути(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._обернути,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Список__обернути,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Список,
      М.константи_назв._обернути,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"обернути\" для структури \"Список\".");
    }
  }
}