// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Список__додати(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"додати\"."));
    }

    змінна предмет_списку = діяльність.здійснювач.дані як *Предмет як *ПредметСписку;

    якщо предмет_списку.клас != М.клас_Список {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"додати\"."));
    }

    змінна задіяне_значення = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._значення, задіяне_значення::адреса);

    записати_в_список(
      М,
      предмет_списку,
      предмет_списку.розмір,
      задіяне_значення
    );

    вернути ЧИСЛО(р64(предмет_списку.розмір));
  }

  дія записати_метод_класу_Список__додати(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._додати,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Список__додати,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Список,
      М.константи_назв._додати,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"додати\" для структури \"Список\".");
    }
  }
}