// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ПеребірСписку__далі(М: *Машина);

  внутрішня дія записати_ознаки_класу_ПеребірСписку(М: *Машина) {
    змінна кількість_ознак = природне(3);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._значення,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[1] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._список,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[2] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._позиція,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_ПеребірСписку.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  дія заповнити_клас_ПеребірСписку(
    М: *Машина
  ) {
    М.клас_ПеребірСписку.вбудований = так;
    М.клас_ПеребірСписку.заборонити_наслідування = так;

    записати_ознаки_класу_ПеребірСписку(М);

    записати_метод_класу_ПеребірСписку__далі(М);
  }

  дія створити_перебір_списку(
    М: *Машина,
    предмет_списку: *ПредметСписку
  ) -> *ПредметПереборуСписку {
    змінна предмет = виділити_предмет<ПредметПереборуСписку>(М, М.клас_ПеребірСписку);

    предмет.предмет_списку = предмет_списку;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = НЕДІЙСНЕ;

    вернути предмет;
  }

  дія здійснити_клас_перебору_списку(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"ПеребірСписку\"."), місцезнаходження);
  }

  дія предмет_перебору_списку_отримати_властивість(
    М: *Машина,
    предмет_перебору_списку: *ПредметПереборуСписку,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути предмет_перебору_списку.поточне_значення;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._список) {
      вернути ПРЕДМЕТ(предмет_перебору_списку.предмет_списку);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._позиція) {
      якщо предмет_перебору_списку.почато {
        вернути ЧИСЛО(р64(предмет_перебору_списку.позиція));
      }
      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПеребірСписку,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}