// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ПеребірДаних__далі(М: *Машина);

  внутрішня дія записати_ознаки_класу_ПеребірДаних(М: *Машина) {
    змінна кількість_ознак = природне(3);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._значення,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[1] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._дані,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[2] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._позиція,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_ПеребірДаних.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  дія заповнити_клас_ПеребірДаних(
    М: *Машина
  ) {
    М.клас_ПеребірДаних.вбудований = так;
    М.клас_ПеребірДаних.заборонити_наслідування = так;

    записати_ознаки_класу_ПеребірДаних(М);

    записати_метод_класу_ПеребірДаних__далі(М);
  }

  дія створити_перебір_даних(
    М: *Машина,
    предмет_даних: *ПредметДаних
  ) -> *ПредметПереборуДаних {
    змінна предмет = виділити_предмет<ПредметПереборуДаних>(М, М.клас_ПеребірДаних);

    предмет.предмет_даних = предмет_даних;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = 0.0;

    вернути предмет;
  }

  дія здійснити_клас_перебору_даних(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"ПеребірДаних\"."), місцезнаходження);
  }

  дія предмет_перебору_даних_отримати_властивість(
    М: *Машина,
    предмет_перебору_даних: *ПредметПереборуДаних,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> Значення {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      якщо предмет_перебору_даних.почато {
        вернути ЧИСЛО(р64(предмет_перебору_даних.поточне_значення));
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._дані) {
      вернути ПРЕДМЕТ(предмет_перебору_даних.предмет_даних);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._позиція) {
      якщо предмет_перебору_даних.почато {
        вернути ЧИСЛО(р64(предмет_перебору_даних.позиція));
      }
      вернути НЕДІЙСНЕ;
    }


    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПеребірДаних,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}