// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія записати_ознаки_класу_Параметр(М: *Машина) {
    змінна кількість_ознак = природне(3);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._назва,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[1] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._тип,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[2] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._значення,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_Параметр.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  дія заповнити_клас_Параметр(
    М: *Машина
  ) {
    М.клас_Параметр.вбудований = так;
    М.клас_Параметр.заборонити_наслідування = так;

    записати_ознаки_класу_Параметр(М);
  }

  дія створити_параметр(
    М: *Машина,
    назва: *ПредметТексту,
    тип: *Предмет,
    значення: Значення
  ) -> *ПредметПараметра {
    змінна предмет = виділити_предмет<ПредметПараметра>(М, М.клас_Параметр);

    предмет.назва = назва;
    предмет.тип = пусто;
    предмет.значення = значення;

    вернути предмет;
  }

  дія здійснити_клас_параметра(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо створити параметр вручну."), місцезнаходження);
  }

  дія предмет_параметра_отримати_властивість(
    М: *Машина,
    предмет_параметра: *ПредметПараметра,
    назва: *ПредметТексту, місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      вернути ПРЕДМЕТ(предмет_параметра.назва);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._тип) {
      якщо предмет_параметра.тип == пусто {
        вернути НЕДІЙСНЕ;
      }
      вернути ПРЕДМЕТ(предмет_параметра.тип);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути предмет_параметра.значення;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Параметр,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}