// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія записати_ознаки_класу_Дія(М: *Машина) {
    змінна кількість_ознак = природне(4);
    змінна дані_ознак = виділити<Значення>(М, кількість_ознак);

    дані_ознак[0] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._назва,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[1] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._параметри,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[2] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._тип_результату,
      пусто,
      НЕДІЙСНЕ
    ));
    дані_ознак[3] = ПРЕДМЕТ(створити_ознаку(
      М,
      М.константи_назв._код,
      пусто,
      НЕДІЙСНЕ
    ));

    М.клас_Дія.ознаки = створити_послідовність_без_копіювання(
      М,
      кількість_ознак,
      дані_ознак
    );
  }

  внутрішня дія записати_властивість_класу_Дія__Параметр(М: *Машина) {
    клас_змінити_властивість(
      М,
      М.клас_Дія,
      М.константи_назв._Параметр,
      ПРЕДМЕТ(М.клас_Параметр),
      Місцезнаходження { пусто, 0 }
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі властивості \"Параметр\" для класу \"Дія\".");
    }
  }

  внутрішня дія записати_властивість_класу_Дія__Код(М: *Машина) {
    клас_змінити_властивість(
      М,
      М.клас_Дія,
      М.константи_назв._Код,
      ПРЕДМЕТ(М.клас_Код),
      Місцезнаходження { пусто, 0 }
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі властивості \"Код\" для класу \"Дія\".");
    }
  }

  дія заповнити_клас_Дія(
    М: *Машина
  ) {
    М.клас_Дія.вбудований = так;
    М.клас_Дія.заборонити_наслідування = так;

    записати_ознаки_класу_Дія(М);

    записати_властивість_класу_Дія__Параметр(М);
    записати_властивість_класу_Дія__Код(М);
  }

  дія створити_дію(
    М: *Машина,
    дійсність_створення: *Дійсність,
    назва: *ПредметТексту,
    параметри: *ПредметПослідовності,
    тип_результату: *Предмет,
    код: *ПредметКоду,
    шлях_до_теки_модулів: *ПредметДаних
  ) -> *ПредметДії {
    змінна предмет = виділити_предмет<ПредметДії>(М, М.клас_Дія);

    предмет.дійсність_створення = дійсність_створення;
    дійсність_створення.кількість_запозичень += 1;

    предмет.рідна = ні;
    предмет.назва = назва;
    предмет.параметри = параметри;
    предмет.код = код;
    предмет.тип_результату = тип_результату;
    предмет.шлях_до_теки_модулів = шлях_до_теки_модулів;
    предмет.метод_класу = пусто;

    вернути предмет;
  }

  дія створити_рідну_дію(
    М: *Машина,
    назва: *ПредметТексту,
    параметри: *ПредметПослідовності,
    тип_результату: *Предмет,
    рідна_дія: РіднаДія,
    шлях_до_теки_модулів: *ПредметДаних
  ) -> *ПредметДії {
    змінна предмет = виділити_предмет<ПредметДії>(М, М.клас_Дія);

    предмет.дійсність_створення = пусто;
    предмет.рідна = так;
    предмет.назва = назва;
    предмет.параметри = параметри;
    предмет.тип_результату = тип_результату;
    предмет.код = рідна_дія;
    предмет.шлях_до_теки_модулів = шлях_до_теки_модулів;
    предмет.метод_класу = пусто;

    вернути предмет;
  }

  дія здійснити_клас_дії(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо створити дію вручну."), місцезнаходження);
  }

  дія предмет_дії_здійснити(
    М: *Машина,
    здійснювач: Значення,
    предмет_дії: *ПредметДії,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо предмет_дії.рідна {
      змінна рідна_дія = предмет_дії.код як РіднаДія;

      змінна діяльність = покласти_в_історію_здійснення(
        М,
        пусто,
        здійснювач,
        предмет_дії,
        задіяні,
        місцезнаходження
      );

      змінна результат = рідна_дія(
        М,
        діяльність
      );

      якщо не М.стан_падіння {
        видалити_з_історії_здійснення(М, 1);
      }

      вернути результат;
    } інакше {
      змінна дійсність = створити_дійсність(
        М,
        предмет_дії.дійсність_створення
      );

      змінна діяльність = покласти_в_історію_здійснення(
        М,
        дійсність,
        здійснювач,
        предмет_дії,
        задіяні,
        місцезнаходження
      );

      змінна розмір_позиційних = задіяні.розмір - (задіяні.кількість_імен * 2);

      якщо предмет_дії.параметри.розмір > 0 {
        змінна п: п32 = 0;

        поки п < п32(предмет_дії.параметри.розмір) {
          змінна параметр = предмет_дії.параметри.елементи[п].дані як *Предмет як *ПредметПараметра;

          якщо п < розмір_позиційних {
            записати_в_дійсність(
              М,
              дійсність,
              параметр.назва,
              задіяні.дані[п]
            );
          } інакше {
            записати_в_дійсність(
              М,
              дійсність,
              параметр.назва,
              параметр.значення
            );
          }

          п += 1;
        }

        якщо задіяні.кількість_імен > 0 {
          п = 0;

          поки п < задіяні.кількість_імен {
            змінна назва = задіяні.дані[розмір_позиційних + задіяні.кількість_імен + п].дані як *Предмет як *ПредметТексту;
            змінна значення = задіяні.дані[розмір_позиційних + п];

            записати_в_дійсність(
              М,
              дійсність,
              назва,
              значення
            );

            п += 1;
          }
        }
      }

      змінна результат = виконати_код(
        М,
        М.накопичувач_значень::адреса,
        діяльність.спроби::адреса,
        дійсність,
        здійснювач,
        предмет_дії.код як *ПредметКоду,
        0,
        предмет_дії.шлях_до_теки_модулів
      );

      якщо М.стан_падіння {
        вернути НЕДІЙСНЕ;
      }

      видалити_з_історії_здійснення(М, 1);

      вернути результат;
    }
  }

  дія предмет_дії_отримати_властивість(
    М: *Машина,
    предмет_дії: *ПредметДії,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      якщо предмет_дії.назва != пусто {
        вернути ПРЕДМЕТ(предмет_дії.назва);
      }

      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._параметри) {
      якщо предмет_дії.параметри != пусто {
        вернути ПРЕДМЕТ(предмет_дії.параметри);
      }

      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._тип_результату) {
      якщо предмет_дії.тип_результату != пусто {
        вернути ПРЕДМЕТ(предмет_дії.тип_результату);
      }

      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._код) {
      якщо не предмет_дії.рідна {
        вернути ПРЕДМЕТ(предмет_дії.код як *ПредметКоду);
      }

      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Дія,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}