// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Список__перетворити(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"перетворити\"."));
    }

    змінна предмет_списку = діяльність.здійснювач.дані як *Предмет як *ПредметСписку;

    якщо предмет_списку.клас != М.клас_Список {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"перетворити\"."));
    }

    змінна задіяне_дія_перетворення = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._дія_перетворення, задіяне_дія_перетворення::адреса);

    змінна новий_список = створити_список(М, предмет_списку.розмір);
    змінна притриманий_список = притримати_глобально(М, новий_список як *Предмет);

    змінна п: природне = 0;

    поки п < предмет_списку.розмір {
      змінна поточне_значення = предмет_списку.елементи[п];

      змінна задіяні = Задіяні { ВидЗадіяних2, 3, виділити<Значення>(М, 3), 0 };
      задіяні.дані[0] = поточне_значення;
      задіяні.дані[1] = ЧИСЛО(р64(п));
      задіяні.дані[2] = ПРЕДМЕТ(предмет_списку);

      змінна результат_здійснення = здійснити(
        М,
        НЕДІЙСНЕ,
        задіяне_дія_перетворення,
        задіяні,
        Місцезнаходження { пусто, 0 }
      );

      якщо М.стан_падіння {
        відпустити_притриманий_глобально(М, притриманий_список);

        вернути НЕДІЙСНЕ;
      }

      записати_в_список(
        М,
        новий_список,
        п,
        результат_здійснення
      );

      п += 1;
    }

    відпустити_притриманий_глобально(М, притриманий_список);

    вернути ПРЕДМЕТ(новий_список);
  }

  дія записати_метод_класу_Список__перетворити(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._перетворити,
      М.пуста_послідовність,
      пусто,
      рідна_дія_методу_структури_Список__перетворити,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Список,
      М.константи_назв._перетворити,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"перетворити\" для структури \"Список\".");
    }
  }
}