// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Список__знайти_позицію(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"знайти_позицію\"."));
    }

    змінна предмет_списку = діяльність.здійснювач.дані як *Предмет як *ПредметСписку;

    якщо предмет_списку.клас != М.клас_Список {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"знайти_позицію\"."));
    }

    змінна задіяне_дія_перевірки = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._дія_перевірки, задіяне_дія_перевірки::адреса);

    змінна п: природне = 0;

    поки п < предмет_списку.розмір {
      змінна поточне_значення = предмет_списку.елементи[п];

      змінна задіяні = Задіяні { 3, виділити<Значення>(М, 3), 0, пусто };
      задіяні.дані[0] = поточне_значення;
      задіяні.дані[1] = ЧИСЛО(р64(п));
      задіяні.дані[2] = ПРЕДМЕТ(предмет_списку);

      змінна результат_здійснення = здійснити(
        М,
        НЕДІЙСНЕ,
        задіяне_дія_перевірки,
        задіяні,
        Місцезнаходження { пусто, 0 }
      );

      якщо М.стан_падіння {
        вернути НЕДІЙСНЕ;
      }

      якщо результат_здійснення.вид != ЗНедійсне {
        вернути ЧИСЛО(р64(п));
      }

      п += 1;
    }

    вернути ЧИСЛО(р64(0)-1);
  }

  дія записати_метод_класу_Список__знайти_позицію(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._знайти_позицію,
      М.предмет_пустої_послідовності,
      пусто,
      рідна_дія_методу_структури_Список__знайти_позицію,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Список,
      М.константи_назв._знайти_позицію,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"знайти_позицію\" для структури \"Список\".");
    }
  }
}