// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Список__забрати(
    М: *Машина,
    діяльність: *Діяльність
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"забрати\"."));
    }

    змінна предмет_списку = діяльність.здійснювач.дані як *Предмет як *ПредметСписку;

    якщо предмет_списку.клас != М.клас_Список {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію списку \"забрати\"."));
    }

    якщо предмет_списку.розмір == 0 {
      вернути НЕДІЙСНЕ;
    }

    предмет_списку.розмір -= 1;

    вернути предмет_списку.елементи[предмет_списку.розмір];
  }

  дія записати_метод_класу_Список__забрати(
    М: *Машина
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._забрати,
      М.предмет_пустої_послідовності,
      пусто,
      рідна_дія_методу_структури_Список__забрати,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Список,
      М.константи_назв._забрати,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"забрати\" для структури \"Список\".");
    }
  }
}