// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ПеребірТексту__далі(М: *Машина);

  внутрішня дія записати_параметри_структури_ПеребірТексту(М: *Машина) {
    змінна кількість_параметрів = природне(3);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._текст,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._позиція,
      пусто,
      пусто
    ));

    М.клас_ПеребірТексту.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_ПеребірТексту(
    М: *Машина
  ) {
    М.клас_ПеребірТексту.вбудований = так;
    М.клас_ПеребірТексту.заборонити_наслідування = так;

    записати_параметри_структури_ПеребірТексту(М);

    записати_метод_класу_ПеребірТексту__далі(М);
  }

  дія створити_перебір_тексту(
    М: *Машина,
    предмет_тексту: *ПредметТексту
  ) -> *ПредметПереборуТексту {
    змінна предмет = виділити_предмет<ПредметПереборуТексту>(М, М.клас_ПеребірТексту);

    предмет.предмет_тексту = предмет_тексту;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = 0.0;

    вернути предмет;
  }

  дія здійснити_клас_перебору_тексту(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"ПеребірТексту\"."), місцезнаходження);
  }

  дія предмет_перебору_тексту_отримати_властивість(
    М: *Машина,
    предмет_перебору_тексту: *ПредметПереборуТексту,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      якщо предмет_перебору_тексту.почато {
        вернути ЧИСЛО(предмет_перебору_тексту.поточне_значення);
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._текст) {
      вернути ПРЕДМЕТ(предмет_перебору_тексту.предмет_тексту);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._позиція) {
      якщо предмет_перебору_тексту.почато {
        вернути ЧИСЛО(р64(предмет_перебору_тексту.позиція));
      }
      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПеребірТексту,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}