// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ПеребірСловника__далі(М: *Машина);

  внутрішня дія записати_параметри_структури_ПеребірСловника(М: *Машина) {
    змінна кількість_параметрів = природне(2);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._словник,
      пусто,
      пусто
    ));

    М.клас_ПеребірСловника.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_ПеребірСловника(
    М: *Машина
  ) {
    М.клас_ПеребірСловника.вбудований = так;
    М.клас_ПеребірСловника.заборонити_наслідування = так;

    записати_параметри_структури_ПеребірСловника(М);

    записати_метод_класу_ПеребірСловника__далі(М);
  }

  дія створити_перебір_словника(
    М: *Машина,
    предмет_словника: *ПредметСловника
  ) -> *ПредметПереборуСловника {
    змінна предмет = виділити_предмет<ПредметПереборуСловника>(М, М.клас_ПеребірСловника);

    предмет.предмет_словника = предмет_словника;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = НЕДІЙСНЕ;

    вернути предмет;
  }

  дія здійснити_клас_перебору_словника(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"ПеребірСловника\"."), місцезнаходження);
  }

  дія предмет_перебору_словника_отримати_властивість(
    М: *Машина,
    предмет_перебору_словника: *ПредметПереборуСловника,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути предмет_перебору_словника.поточне_значення;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._словник) {
      вернути ПРЕДМЕТ(предмет_перебору_словника.предмет_словника);
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПеребірСловника,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}