// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ПеребірПослідовності__далі(М: *Машина);

  внутрішня дія записати_параметри_структури_ПеребірПослідовності(М: *Машина) {
    змінна кількість_параметрів = природне(3);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._послідовність,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._позиція,
      пусто,
      пусто
    ));

    М.клас_ПеребірПослідовності.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_ПеребірПослідовності(
    М: *Машина
  ) {
    М.клас_ПеребірПослідовності.вбудований = так;
    М.клас_ПеребірПослідовності.заборонити_наслідування = так;

    записати_параметри_структури_ПеребірПослідовності(М);

    записати_метод_класу_ПеребірПослідовності__далі(М);
  }

  дія створити_перебір_послідовності(
    М: *Машина,
    предмет_послідовності: *ПредметПослідовності
  ) -> *ПредметПереборуПослідовності {
    змінна предмет = виділити_предмет<ПредметПереборуПослідовності>(М, М.клас_ПеребірПослідовності);

    предмет.предмет_послідовності = предмет_послідовності;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = НЕДІЙСНЕ;

    вернути предмет;
  }

  дія здійснити_клас_перебору_послідовності(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"ПеребірПослідовності\"."), місцезнаходження);
  }

  дія предмет_перебору_послідовності_отримати_властивість(
    М: *Машина,
    предмет_перебору_послідовності: *ПредметПереборуПослідовності,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      якщо предмет_перебору_послідовності.почато {
        вернути предмет_перебору_послідовності.поточне_значення;
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._послідовність) {
      вернути ПРЕДМЕТ(предмет_перебору_послідовності.предмет_послідовності);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._позиція) {
      якщо предмет_перебору_послідовності.почато {
        вернути ЧИСЛО(р64(предмет_перебору_послідовності.позиція));
      }
      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПеребірПослідовності,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}