// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ПеребірДіапазонуЧисел__далі(М: *Машина);

  внутрішня дія записати_параметри_структури_ПеребірДіапазонуЧисел(М: *Машина) {
    змінна кількість_параметрів = природне(2);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._діапазон,
      пусто,
      пусто
    ));

    М.клас_ПеребірДіапазонуЧисел.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_ПеребірДіапазонуЧисел(
    М: *Машина
  ) {
    М.клас_ПеребірДіапазонуЧисел.вбудований = так;
    М.клас_ПеребірДіапазонуЧисел.заборонити_наслідування = так;

    записати_параметри_структури_ПеребірДіапазонуЧисел(М);

    записати_метод_класу_ПеребірДіапазонуЧисел__далі(М);
  }

  дія створити_перебір_діапазону_чисел(
    М: *Машина,
    предмет_діапазону: *ПредметДіапазонуЧисел
  ) -> *ПредметПереборуДіапазонуЧисел {
    змінна предмет = виділити_предмет<ПредметПереборуДіапазонуЧисел>(М, М.клас_ПеребірДіапазонуЧисел);

    предмет.предмет_діапазону = предмет_діапазону;
    предмет.почато = ні;
    предмет.поточне_значення = 0.0;

    вернути предмет;
  }

  дія здійснити_клас_перебору_діапазону_чисел(
    М: *Машина,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"ПеребірДіапазонуЧисел\"."), місцезнаходження);
  }

  дія предмет_перебору_діапазону_чисел_отримати_властивість(
    М: *Машина,
    предмет_перебору_діапазону_чисел: *ПредметПереборуДіапазонуЧисел,
    назва: *ПредметТексту,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      якщо предмет_перебору_діапазону_чисел.почато {
        вернути ЧИСЛО(предмет_перебору_діапазону_чисел.поточне_значення);
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._діапазон) {
      вернути ПРЕДМЕТ(предмет_перебору_діапазону_чисел.предмет_діапазону);
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПеребірДіапазонуЧисел,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}