// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_Текст__чародія_число(М: адреса<Машина>);
  дія записати_метод_класу_Текст__чародія_текст(М: адреса<Машина>);
  дія записати_метод_класу_Текст__чародія_перебір(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_Текст(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(1);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._розмір,
      пусто,
      пусто
    ));

    М.клас_Текст.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія записати_дію_структури_Текст__з(М: адреса<Машина>);

  дія заповнити_клас_Текст(
    М: адреса<Машина>
  ) {
    М.клас_Текст.вбудований = так;
    М.клас_Текст.заборонити_наслідування = так;

    записати_параметри_структури_Текст(М);

    записати_метод_класу_Текст__чародія_число(М);
    записати_метод_класу_Текст__чародія_текст(М);
    записати_метод_класу_Текст__чародія_перебір(М);

    записати_дію_структури_Текст__з(М);
  }

  дія створити_текст(
    М: адреса<Машина>,
    значення: кд
  ) -> адреса<ПредметТексту> {
    змінна предмет = виділити_предмет<ПредметТексту>(М, М.клас_Текст);

    змінна копія_тексту = виділити<п8>(М, значення.розмір);

    змінна п: природне = 0;
    поки п < значення.розмір {
      копія_тексту[п] = значення.дані[п];

      п += 1;
    }

    предмет.значення = кд { значення.розмір, копія_тексту };

    вернути предмет;
  }

  дія створити_текст_без_копіювання(
    М: адреса<Машина>,
    розмір: природне,
    дані: адреса<п8>
  ) -> адреса<ПредметТексту> {
    змінна предмет = виділити_предмет<ПредметТексту>(М, М.клас_Текст);

    предмет.значення = кд { розмір, дані };

    вернути предмет;
  }

  дія здійснити_клас_тексту(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"Текст\"."), місцезнаходження);
  }

  дія предмет_тексту_отримати_властивість(
    М: адреса<Машина>,
    предмет_тексту: адреса<ПредметТексту>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._розмір) {
      вернути ЧИСЛО(р64(предмет_тексту.значення.розмір));
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Текст,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_тексту_отримати_елемент(
    М: адреса<Машина>,
    предмет_тексту: адреса<ПредметТексту>,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути НЕДІЙСНЕ;
  }
}