// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_Список__чародія_текст(М: адреса<Машина>);
  дія записати_метод_класу_Список__чародія_перебір(М: адреса<Машина>);
  дія записати_метод_класу_Список__додати(М: адреса<Машина>);
  дія записати_метод_класу_Список__забрати(М: адреса<Машина>);
  дія записати_метод_класу_Список__знайти(М: адреса<Машина>);
  дія записати_метод_класу_Список__знайти_позицію(М: адреса<Машина>);
  дія записати_метод_класу_Список__фільтрований(М: адреса<Машина>);
  дія записати_метод_класу_Список__перетворений(М: адреса<Машина>);
  дія записати_метод_класу_Список__обернений(М: адреса<Машина>);
  дія записати_метод_класу_Список__містить(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_Список(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(1);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._розмір,
      пусто,
      пусто
    ));

    М.клас_Список.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_Список(
    М: адреса<Машина>
  ) {
    М.клас_Список.вбудований = так;
    М.клас_Список.заборонити_наслідування = так;

    записати_параметри_структури_Список(М);

    записати_метод_класу_Список__чародія_текст(М);
    записати_метод_класу_Список__чародія_перебір(М);
    записати_метод_класу_Список__додати(М);
    записати_метод_класу_Список__забрати(М);
    записати_метод_класу_Список__знайти(М);
    записати_метод_класу_Список__знайти_позицію(М);
    записати_метод_класу_Список__фільтрований(М);
    записати_метод_класу_Список__перетворений(М);
    записати_метод_класу_Список__обернений(М);
    записати_метод_класу_Список__містить(М);
  }

  дія створити_список(
    М: адреса<Машина>,
    розмір: природне
  ) -> адреса<ПредметСписку> {
    змінна предмет = виділити_предмет<ПредметСписку>(М, М.клас_Список);

    змінна дані: адреса<Значення> = пусто;

    якщо розмір > 0 {
      дані = виділити<Значення>(М, розмір);
      змінна п: природне = 0;

      поки п < розмір {
        дані[п] = НЕДІЙСНЕ;

        п += 1;
      }
    }

    предмет.розмір = розмір;
    предмет.елементи = дані;

    вернути предмет;
  }

  дія записати_в_список(
    М: адреса<Машина>,
    предмет_списку: адреса<ПредметСписку>,
    позиція: природне,
    значення: Значення
  ) {
    якщо позиція >= предмет_списку.розмір {
      предмет_списку.елементи = перевиділити<Значення>(М, предмет_списку.елементи, позиція + 1);

      змінна п = предмет_списку.розмір;

      поки п < позиція + 1 {

        предмет_списку.елементи[п] = НЕДІЙСНЕ;

        п += 1;
      }

      предмет_списку.розмір = позиція + 1;
    }

    предмет_списку.елементи[позиція] = значення;
  }

  дія здійснити_клас_списку(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"Список\"."), місцезнаходження);
  }

  дія предмет_списку_отримати_властивість(
    М: адреса<Машина>,
    предмет_списку: адреса<ПредметСписку>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._розмір) {
      вернути ЧИСЛО(р64(предмет_списку.розмір));
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Список,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_списку_отримати_елемент(
    М: адреса<Машина>,
    предмет_списку: адреса<ПредметСписку>,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо ключ.вид == ЗЧисло {
      змінна позиція = природне(ключ.дані як р64);

      якщо позиція >= 0 і позиція < предмет_списку.розмір {
        вернути предмет_списку.елементи[позиція];
      }
    }

    вернути НЕДІЙСНЕ;
  }

  дія предмет_списку_змінити_елемент(
    М: адреса<Машина>,
    предмет_списку: адреса<ПредметСписку>,
    ключ: Значення,
    значення_елемента: Значення,
    місцезнаходження: Місцезнаходження
  ) -> СтанПадіння {
    якщо ключ.вид == ЗЧисло {
      змінна позиція = ключ.дані як р64;

      якщо позиція >= 0 {
        записати_в_список(М, предмет_списку, природне(позиція), значення_елемента);
      }
    }
  }
}