// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_Послідовність__чародія_перебір(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_Послідовність(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(1);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._розмір,
      пусто,
      пусто
    ));

    М.клас_Послідовність.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_Послідовність(
    М: адреса<Машина>
  ) {
    М.клас_Послідовність.вбудований = так;
    М.клас_Послідовність.заборонити_наслідування = так;

    записати_параметри_структури_Послідовність(М);

    записати_метод_класу_Послідовність__чародія_перебір(М);
  }

  дія створити_послідовність(
    М: адреса<Машина>,
    розмір: природне,
    елементи: адреса<Значення>
  ) -> адреса<ПредметПослідовності> {
    змінна копія_елементів = виділити<Значення>(М, розмір);

    змінна п: природне = 0;
    поки п < розмір {
      копія_елементів[п] = елементи[п];
      п += 1;
    }

    змінна послідовність = виділити_предмет<ПредметПослідовності>(М, М.клас_Послідовність);

    послідовність.розмір = розмір;
    послідовність.елементи = копія_елементів;

    вернути послідовність;
  }

  дія створити_послідовність_без_копіювання(
    М: адреса<Машина>,
    розмір: природне,
    елементи: адреса<Значення>
  ) -> адреса<ПредметПослідовності> {
    змінна послідовність = виділити_предмет<ПредметПослідовності>(М, М.клас_Послідовність);

    послідовність.розмір = розмір;
    послідовність.елементи = елементи;

    вернути послідовність;
  }

  дія створити_сиру_послідовність(
    М: адреса<Машина>,
    розмір: природне
  ) -> адреса<ПредметПослідовності> {
    змінна послідовність = виділити_предмет<ПредметПослідовності>(М, М.клас_Послідовність);

    послідовність.розмір = розмір;
    послідовність.елементи = виділити<Значення>(М, розмір);

    вернути послідовність;
  }

  дія здійснити_клас_послідовності(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути ПРЕДМЕТ(створити_послідовність(
      М,
      задіяні.розмір - задіяні.розмір_імен,
      задіяні.дані
    ));
  }

  дія предмет_послідовності_отримати_властивість(
    М: адреса<Машина>,
    предмет_послідовності: адреса<ПредметПослідовності>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._розмір) {
      вернути ЧИСЛО(р64(предмет_послідовності.розмір));
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Послідовність,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_послідовності_отримати_елемент(
    М: адреса<Машина>,
    предмет_послідовності: адреса<ПредметПослідовності>,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути НЕДІЙСНЕ;
  }
}