// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ПеребірСписку__далі(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_ПеребірСписку(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(3);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._список,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._позиція,
      пусто,
      пусто
    ));

    М.клас_ПеребірСписку.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_ПеребірСписку(
    М: адреса<Машина>
  ) {
    М.клас_ПеребірСписку.вбудований = так;
    М.клас_ПеребірСписку.заборонити_наслідування = так;

    записати_параметри_структури_ПеребірСписку(М);

    записати_метод_класу_ПеребірСписку__далі(М);
  }

  дія створити_перебір_списку(
    М: адреса<Машина>,
    предмет_списку: адреса<ПредметСписку>
  ) -> адреса<ПредметПереборуСписку> {
    змінна предмет = виділити_предмет<ПредметПереборуСписку>(М, М.клас_ПеребірСписку);

    предмет.предмет_списку = предмет_списку;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = НЕДІЙСНЕ;

    вернути предмет;
  }

  дія здійснити_клас_перебору_списку(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити клас \"ПеребірСписку\"."), місцезнаходження);
  }

  дія предмет_перебору_списку_отримати_властивість(
    М: адреса<Машина>,
    предмет_перебору_списку: адреса<ПредметПереборуСписку>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути предмет_перебору_списку.поточне_значення;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._список) {
      вернути ПРЕДМЕТ(предмет_перебору_списку.предмет_списку);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._позиція) {
      якщо предмет_перебору_списку.почато {
        вернути ЧИСЛО(р64(предмет_перебору_списку.позиція));
      }
      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ПеребірСписку,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}