// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія записати_параметри_структури_Код(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(4);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._константи,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._вказівки,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._шлях,
      пусто,
      пусто
    ));
    дані_параметрів[3] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._місцезнаходження_вказівок,
      пусто,
      пусто
    ));

    М.клас_Код.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_Код(
    М: адреса<Машина>
  ) {
    М.клас_Код.вбудований = так;
    М.клас_Код.заборонити_наслідування = так;

    записати_параметри_структури_Код(М);
  }

  дія створити_код(
    М: адреса<Машина>,
    константи: адреса<ПредметПослідовності>,
    вказівки: адреса<ПредметДаних>,
    шлях: адреса<ПредметДаних>,
    місцезнаходження_вказівок: МісцезнаходженняВказівок
  ) -> адреса<ПредметКоду> {
    змінна предмет = виділити_предмет<ПредметКоду>(М, М.клас_Код);

    предмет.константи = константи;
    предмет.вказівки = вказівки;
    предмет.шлях = шлях;
    предмет.місцезнаходження_вказівок = місцезнаходження_вказівок;

    вернути предмет;
  }

  дія здійснити_клас_коду(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо створити код вручну."), місцезнаходження);
  }

  дія предмет_коду_отримати_властивість(
    М: адреса<Машина>,
    предмет_коду: адреса<ПредметКоду>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._константи) {
      якщо предмет_коду.константи != пусто {
        вернути ПРЕДМЕТ(предмет_коду.константи);
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._вказівки) {
      якщо предмет_коду.вказівки != пусто {
        вернути ПРЕДМЕТ(предмет_коду.вказівки);
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._шлях) {
      якщо предмет_коду.шлях != пусто {
        вернути ПРЕДМЕТ(предмет_коду.шлях);
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._місцезнаходження_вказівок) {
      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Код,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія знайти_рядок_вказівки(
    місцезнаходження_вказівок: МісцезнаходженняВказівок,
    позиція_вказівки: п32
  ) -> п32 {
    змінна п: природне = 0;

    поки п < місцезнаходження_вказівок.розмір {
      змінна м = місцезнаходження_вказівок.дані[п];

      якщо м.початок <= позиція_вказівки {
        якщо м.кінець >= позиція_вказівки {
          вернути м.рядок;
        }
      }

      п += 1;
    }

    вернути 0;
  }
}