// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_ДіапазонЧисел__чародія_перебір(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_ДіапазонЧисел(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(3);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._від,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._до,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._включно,
      пусто,
      пусто
    ));

    М.клас_ДіапазонЧисел.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_ДіапазонЧисел(
    М: адреса<Машина>
  ) {
    М.клас_ДіапазонЧисел.вбудований = так;
    М.клас_ДіапазонЧисел.заборонити_наслідування = так;

    записати_параметри_структури_ДіапазонЧисел(М);

    записати_метод_класу_ДіапазонЧисел__чародія_перебір(М);
  }

  дія створити_діапазон_чисел(
    М: адреса<Машина>,
    від: р64,
    до: р64,
    включно: логічне
  ) -> адреса<ПредметДіапазонуЧисел> {
    змінна предмет = виділити_предмет<ПредметДіапазонуЧисел>(М, М.клас_ДіапазонЧисел);

    предмет.від = від;
    предмет.до = до;
    предмет.включно = включно;

    вернути предмет;
  }

  дія здійснити_клас_діапазону_чисел(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна задіяне_від = НЕДІЙСНЕ;
    змінна задіяне_до = НЕДІЙСНЕ;
    змінна задіяне_включно = НЕДІЙСНЕ;

    знайти_задіяне(М, задіяні, 0, М.константи_назв._від, задіяне_від::адреса);
    знайти_задіяне(М, задіяні, 1, М.константи_назв._до, задіяне_до::адреса);
    знайти_задіяне(М, задіяні, 2, М.константи_назв._включно, задіяне_включно::адреса);

    змінна від = р64(0.0);
    змінна до = р64(0.0);
    змінна включно = задіяне_включно.вид != ЗНедійсне;

    якщо задіяне_від.вид == ЗЧисло {
      від = задіяне_від.дані як р64;
    } інакше {
      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Задіяне \"від\" має бути числом."), місцезнаходження);
    }
    якщо задіяне_до.вид == ЗЧисло {
      до = задіяне_до.дані як р64;
    } інакше {
      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Задіяне \"до\" має бути числом."), місцезнаходження);
    }

    вернути ПРЕДМЕТ(створити_діапазон_чисел(
      М,
      від,
      до,
      включно
    ));
  }

  дія предмет_діапазону_чисел_отримати_властивість(
    М: адреса<Машина>,
    предмет_діапазону_чисел: адреса<ПредметДіапазонуЧисел>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._від) {
      вернути ЧИСЛО(предмет_діапазону_чисел.від);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._до) {
      вернути ЧИСЛО(предмет_діапазону_чисел.до);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._включно) {
      вернути ЛОГЛОГ(предмет_діапазону_чисел.включно);
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_ДіапазонЧисел,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}