// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  дія записати_метод_класу_Дані__чародія_перебір(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_Дані(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(1);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._розмір,
      пусто,
      пусто
    ));

    М.клас_Дані.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_Дані(
    М: адреса<Машина>
  ) {
    М.клас_Дані.вбудований = так;
    М.клас_Дані.заборонити_наслідування = так;

    записати_параметри_структури_Дані(М);

    записати_метод_класу_Дані__чародія_перебір(М);
  }

  дія створити_дані(
    М: адреса<Машина>,
    розмір: природне,
    дані: адреса<п8>
  ) -> адреса<ПредметДаних> {
    змінна предмет = виділити_предмет<ПредметДаних>(М, М.клас_Дані);
    змінна копія_даних = виділити<п8>(М, розмір);

    змінна п: природне = 0;
    поки п < розмір {
      копія_даних[п] = дані[п];
      п += 1;
    }

    предмет.розмір = розмір;
    предмет.дані = копія_даних;

    вернути предмет;
  }

  дія створити_дані_без_копіювання(
    М: адреса<Машина>,
    розмір: природне,
    дані: адреса<п8>
  ) -> адреса<ПредметДаних> {
    змінна предмет = виділити_предмет<ПредметДаних>(М, М.клас_Дані);

    предмет.розмір = розмір;
    предмет.дані = дані;

    вернути предмет;
  }

  дія здійснити_клас_даних(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна задіяне_розмір = НЕДІЙСНЕ;
    змінна знайдено_задіяне_розмір = ні;

    знайдено_задіяне_розмір = знайти_задіяне(М, задіяні, 0, М.константи_назв._розмір, задіяне_розмір::адреса);

    якщо не знайдено_задіяне_розмір {
      вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"розмір\" має бути числом."));
    }

    якщо задіяне_розмір.вид != ЗЧисло {
      вернути ПАДІННЯ(М, створити_текст(М, "Задіяне \"розмір\" має бути числом."));
    }

    змінна розмір = природне(задіяне_розмір.дані як р64);
    змінна дані = виділити<п8>(М, розмір);

    вернути ПРЕДМЕТ(створити_дані_без_копіювання(
      М,
      розмір,
      дані
    ));
  }

  дія предмет_даних_отримати_властивість(
    М: адреса<Машина>,
    предмет_даних: адреса<ПредметДаних>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._розмір) {
      вернути ЧИСЛО(р64(предмет_даних.розмір));
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Дані,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_даних_отримати_елемент(
    М: адреса<Машина>,
    предмет_даних: адреса<ПредметДаних>,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо ключ.вид != ЗЧисло {
      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Ключ для отримання елемента даних має бути числом."), місцезнаходження);
    }

    змінна позиція = природне(ключ.дані як р64);

    якщо позиція >= предмет_даних.розмір {
      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Позиція для отримання елемента даних виходить за межі."), місцезнаходження);
    }

    вернути ЧИСЛО(р64(предмет_даних.дані[позиція]));
  }

  дія предмет_даних_змінити_елемент(
    М: адреса<Машина>,
    предмет_даних: адреса<ПредметДаних>,
    ключ: Значення,
    значення: Значення,
    місцезнаходження: Місцезнаходження
  ) -> СтанПадіння {
    якщо ключ.вид != ЗЧисло {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Ключ для зміни елемента даних має бути числом."), місцезнаходження);
      вернути;
    }

    якщо значення.вид != ЗЧисло {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Значення для зміни елемента даних має бути числом."), місцезнаходження);
      вернути;
    }

    змінна позиція = природне(ключ.дані як р64);

    якщо позиція >= предмет_даних.розмір {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Позиція для зміни елемента даних виходить за межі."), місцезнаходження);
      вернути;
    }

    предмет_даних.дані[позиція] = п8(значення.дані як р64);
  }
}