// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_методу_структури_Словник__містить(
    М: адреса<Машина>,
    діяльність: адреса<Діяльність>
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію словника \"містить\"."));
    }

    змінна предмет_словника = діяльність.здійснювач.дані як адреса<Предмет> як адреса<ПредметСловника>;

    якщо предмет_словника.клас != М.клас_Словник {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію словника \"містить\"."));
    }

    змінна задіяне_ключ = НЕДІЙСНЕ;

    знайти_задіяне(М, діяльність.задіяні, 0, М.константи_назв._ключ, задіяне_ключ::адреса);

    змінна п: природне = 0;

    поки п < предмет_словника.розмір {
      якщо перевірити_чи_значення_рівні(М, предмет_словника.елементи[п].ключ, задіяне_ключ) {
        вернути ДІЙСНЕ;
      }

      п += 1;
    }

    вернути НЕДІЙСНЕ;
  }

  дія записати_метод_класу_Словник__містить(
    М: адреса<Машина>
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._містить,
      М.предмет_пустої_послідовності,
      пусто,
      рідна_дія_методу_структури_Словник__містить,
      пусто
    );

    записати_метод_класу(
      М,
      М.клас_Словник,
      М.константи_назв._містить,
      предмет_дії
    );

    якщо М.стан_падіння {
      ЗАПАНІКУВАТИ(М, "Помилка при записі дії \"містить\" для структури \"Словник\".");
    }
  }
}