// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти визначення мавка/машина;

простір мавка {
  внутрішня дія записати_параметри_класу_Клас(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(3);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._назва,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._предок,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._параметри,
      пусто,
      пусто
    ));

    М.клас_Клас.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_клас_Клас(
    М: адреса<Машина>
  ) {
    М.клас_Клас.вбудований = так;
    М.клас_Клас.заборонити_наслідування = так;

    записати_параметри_класу_Клас(М);
  }

  дія створити_клас(
    М: адреса<Машина>,
    назва: адреса<ПредметТексту>,
    параметри: адреса<ПредметПослідовності>
  ) -> адреса<ПредметКласу> {
    змінна предмет = виділити_предмет<ПредметКласу>(М, М.клас_Клас);

    предмет.вбудований = ні;
    предмет.заборонити_наслідування = ні;
    предмет.назва = назва;
    предмет.параметри = параметри;
    предмет.методи = Методи { 0, пусто };
    предмет.властивості = Призначення { 0, пусто, 0 };

    вернути предмет;
  }

  дія змінити_властивість_класу(
    М: адреса<Машина>,
    предмет_класу: адреса<ПредметКласу>,
    назва: адреса<ПредметТексту>,
    значення: Значення,
  ) {
    призначити(
      М,
      предмет_класу.властивості::адреса,
      назва,
      значення
    );
  }

  // позначка: прохід по типах предметів
  дія клас_здійснити(
    М: адреса<Машина>,
    предмет_класу: адреса<ПредметКласу>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо предмет_класу.вбудований {
      якщо предмет_класу == М.клас_Модуль {
        вернути здійснити_структуру_модуля(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Параметр {
        вернути здійснити_структуру_параметра(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Число {
        вернути здійснити_структуру_числа(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Текст {
        вернути здійснити_структуру_тексту(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Код {
        вернути здійснити_структуру_коду(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Дія {
        вернути здійснити_структуру_дії(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Список {
        вернути здійснити_структуру_списку(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Словник {
        вернути здійснити_структуру_словника(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Дані {
        вернути здійснити_структуру_даних(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ДіапазонЧисел {
        вернути здійснити_структуру_діапазону_чисел(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірДіапазонуЧисел {
        вернути здійснити_структуру_перебору_діапазону_чисел(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірДаних {
        вернути здійснити_структуру_перебору_даних(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірПослідовності {
        вернути здійснити_структуру_перебору_послідовності(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірСловника {
        вернути здійснити_структуру_перебору_словника(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірСписку {
        вернути здійснити_структуру_перебору_списку(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_ПеребірТексту {
        вернути здійснити_структуру_перебору_тексту(М, задіяні, місцезнаходження);
      }

      якщо предмет_класу == М.клас_Послідовність {
        вернути здійснити_структуру_послідовності(М, задіяні, місцезнаходження);
      }

      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити структуру."), місцезнаходження);
    }

    змінна предмет = створити_складений_предмет(М, предмет_класу);

    змінна предмет_метода = знайти_метод_в_класі(
      М,
      предмет_класу,
      М.константи_назв._чародія
    );

    якщо предмет_метода != пусто {
      предмет_дії_здійснити(
        М,
        ПРЕДМЕТ(предмет),
        предмет_метода,
        задіяні,
        місцезнаходження
      );

      вернути ПРЕДМЕТ(предмет);
    }

    покласти_в_історію_здійснення(
      М,
      пусто,
      ПРЕДМЕТ(предмет),
      пусто,
      задіяні,
      місцезнаходження
    );

    якщо предмет_класу.параметри.розмір > 0 {
      змінна п: природне = 0;

      поки п < предмет_класу.параметри.розмір {
        змінна параметр = предмет_класу.параметри.елементи[п];
        змінна властивості_параметра = параметр.дані як адреса<Предмет> як адреса<ПредметПараметра>;

        якщо (задіяні.розмір - задіяні.розмір_імен) > п {
          призначити(
            М,
            предмет.властивості::адреса,
            властивості_параметра.назва,
            задіяні.дані[п]
          );
        }

        п += 1;
      }

      якщо задіяні.розмір_імен > 0 {
        п = 0;

        поки п < задіяні.розмір_імен {
          змінна назва = задіяні.дані_імен[п];
          змінна значення = задіяні.дані[задіяні.розмір - задіяні.розмір_імен + п];

          призначити(
            М,
            предмет.властивості::адреса,
            назва,
            значення
          );

          п += 1;
        }
      }
    }

    видалити_з_історії_здійснення(М, 1);

    вернути ПРЕДМЕТ(предмет);
  }

  дія записати_метод_класу(
    М: адреса<Машина>,
    предмет_класу: адреса<ПредметКласу>,
    назва: адреса<ПредметТексту>,
    значення_дії: адреса<ПредметДії>
  ) {
    змінна п: природне = 0;

    поки п < предмет_класу.методи.розмір {
      змінна метод = предмет_класу.методи.дані[п]::адреса;

      якщо перевірити_чи_предмети_тексту_рівні(М, метод.назва, назва) {
        метод.значення = значення_дії;

        вернути;
      }

      п += 1;
    }

    предмет_класу.методи.дані = перевиділити<Метод>(М, предмет_класу.методи.дані, предмет_класу.методи.розмір + 1);
    предмет_класу.методи.дані[предмет_класу.методи.розмір] = Метод { назва, значення_дії };
    предмет_класу.методи.розмір += 1;
  }

  дія знайти_метод_в_класі(
    М: адреса<Машина>,
    предмет_класу: адреса<ПредметКласу>,
    назва: адреса<ПредметТексту>
  ) -> адреса<ПредметДії> {
    змінна п: природне = 0;

    поки п < предмет_класу.методи.розмір {
      змінна метод = предмет_класу.методи.дані[п];

      якщо перевірити_чи_предмети_тексту_рівні(М, метод.назва, назва) {
        вернути метод.значення;
      }

      п += 1;
    }

    вернути пусто;
  }

  дія клас_отримати_властивість(
    М: адреса<Машина>,
    предмет_класу: адреса<ПредметКласу>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      якщо предмет_класу.назва == пусто {
        вернути НЕДІЙСНЕ;
      }
      вернути ПРЕДМЕТ(предмет_класу.назва);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._параметри) {
      вернути ПРЕДМЕТ(предмет_класу.параметри);
    }

    змінна значення_властивості = НЕДІЙСНЕ;

    якщо знайти_призначене(
      М,
      предмет_класу.властивості,
      назва,
      значення_властивості::адреса
    ) {
      вернути значення_властивості;
    }

    змінна предмет_методу = знайти_метод_в_класі(
      М,
      М.клас_Клас,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія клас_змінити_властивість(
    М: адреса<Машина>,
    предмет_класу: адреса<ПредметКласу>,
    назва: адреса<ПредметТексту>,
    значення: Значення,
    місцезнаходження: Місцезнаходження
  ) {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо змінити назву структури."), місцезнаходження);
      вернути;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._параметри) {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо змінити параметри структури."), місцезнаходження);
      вернути;
    }

    змінити_властивість_класу(
      М,
      предмет_класу,
      назва,
      значення
    );
  }
}