// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  внутрішня дія записати_параметри_структури_Структура(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(2);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._назва,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._параметри,
      пусто,
      пусто
    ));

    М.предмет_структури_Структура.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_структуру_Структура(
    М: адреса<Машина>
  ) {
    М.предмет_структури_Структура.вбудована = так;
    М.предмет_структури_Структура.заборонити_наслідування = так;

    записати_параметри_структури_Структура(М);
  }

  дія створити_структуру(
    М: адреса<Машина>,
    назва: адреса<ПредметТексту>,
    параметри: адреса<ПредметПослідовності>
  ) -> адреса<ПредметСтруктури> {
    змінна предмет = виділити_предмет<ПредметСтруктури>(М, М.предмет_структури_Структура);

    предмет.вбудована = ні;
    предмет.заборонити_наслідування = ні;
    предмет.назва = назва;
    предмет.параметри = параметри;
    предмет.методи = Методи { 0, пусто };
    предмет.властивості = Призначення { 0, пусто, 0 };

    вернути предмет;
  }

  дія змінити_властивість_структури(
    М: адреса<Машина>,
    предмет_структури: адреса<ПредметСтруктури>,
    назва: адреса<ПредметТексту>,
    значення: Значення,
  ) {
    призначити(
      М,
      предмет_структури.властивості::адреса,
      назва,
      значення
    );
  }

  // позначка: прохід по типах предметів
  дія предмет_структури_здійснити(
    М: адреса<Машина>,
    предмет_структури: адреса<ПредметСтруктури>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо предмет_структури.вбудована {
      якщо предмет_структури == М.предмет_структури_Модуль {
        вернути здійснити_структуру_модуля(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Параметр {
        вернути здійснити_структуру_параметра(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Число {
        вернути здійснити_структуру_числа(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Текст {
        вернути здійснити_структуру_тексту(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Код {
        вернути здійснити_структуру_коду(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Дія {
        вернути здійснити_структуру_дії(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Список {
        вернути здійснити_структуру_списку(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Словник {
        вернути здійснити_структуру_словника(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Дані {
        вернути здійснити_структуру_даних(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_ДіапазонЧисел {
        вернути здійснити_структуру_діапазону_чисел(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_ПеребірДіапазонуЧисел {
        вернути здійснити_структуру_перебору_діапазону_чисел(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_ПеребірДаних {
        вернути здійснити_структуру_перебору_даних(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_ПеребірПослідовності {
        вернути здійснити_структуру_перебору_послідовності(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_ПеребірСловника {
        вернути здійснити_структуру_перебору_словника(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_ПеребірСписку {
        вернути здійснити_структуру_перебору_списку(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_ПеребірТексту {
        вернути здійснити_структуру_перебору_тексту(М, задіяні, місцезнаходження);
      }

      якщо предмет_структури == М.предмет_структури_Послідовність {
        вернути здійснити_структуру_послідовності(М, задіяні, місцезнаходження);
      }

      вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити структуру."), місцезнаходження);
    }

    змінна предмет = створити_складений_предмет(М, предмет_структури);

    змінна предмет_метода = знайти_метод_в_структурі(
      М,
      предмет_структури,
      М.константи_назв._чародія
    );

    якщо предмет_метода != пусто {
      предмет_дії_здійснити(
        М,
        ПРЕДМЕТ(предмет),
        предмет_метода,
        задіяні,
        місцезнаходження
      );

      вернути ПРЕДМЕТ(предмет);
    }

    покласти_в_історію_здійснення(
      М,
      пусто,
      ПРЕДМЕТ(предмет),
      пусто,
      задіяні,
      місцезнаходження
    );

    якщо предмет_структури.параметри.розмір > 0 {
      змінна п: природне = 0;

      поки п < предмет_структури.параметри.розмір {
        змінна параметр = предмет_структури.параметри.елементи[п];
        змінна властивості_параметра = параметр.дані як адреса<Предмет> як адреса<ПредметПараметра>;

        якщо (задіяні.розмір - задіяні.розмір_імен) > п {
          призначити(
            М,
            предмет.властивості::адреса,
            властивості_параметра.назва,
            задіяні.дані[п]
          );
        }

        п += 1;
      }

      якщо задіяні.розмір_імен > 0 {
        п = 0;

        поки п < задіяні.розмір_імен {
          змінна назва = задіяні.дані_імен[п];
          змінна значення = задіяні.дані[задіяні.розмір - задіяні.розмір_імен + п];

          призначити(
            М,
            предмет.властивості::адреса,
            назва,
            значення
          );

          п += 1;
        }
      }
    }

    видалити_з_історії_здійснення(М, 1);

    вернути ПРЕДМЕТ(предмет);
  }

  дія записати_метод_структури(
    М: адреса<Машина>,
    предмет_структури: адреса<ПредметСтруктури>,
    назва: адреса<ПредметТексту>,
    значення_дії: адреса<ПредметДії>
  ) {
    змінна п: природне = 0;

    поки п < предмет_структури.методи.розмір {
      змінна метод = предмет_структури.методи.дані[п]::адреса;

      якщо перевірити_чи_предмети_тексту_рівні(М, метод.назва, назва) {
        метод.значення = значення_дії;

        вернути;
      }

      п += 1;
    }

    предмет_структури.методи.дані = перевиділити<Метод>(М, предмет_структури.методи.дані, предмет_структури.методи.розмір + 1);
    предмет_структури.методи.дані[предмет_структури.методи.розмір] = Метод { назва, значення_дії };
    предмет_структури.методи.розмір += 1;
  }

  дія знайти_метод_в_структурі(
    М: адреса<Машина>,
    предмет_структури: адреса<ПредметСтруктури>,
    назва: адреса<ПредметТексту>
  ) -> адреса<ПредметДії> {
    змінна п: природне = 0;

    поки п < предмет_структури.методи.розмір {
      змінна метод = предмет_структури.методи.дані[п];

      якщо перевірити_чи_предмети_тексту_рівні(М, метод.назва, назва) {
        вернути метод.значення;
      }

      п += 1;
    }

    вернути пусто;
  }

  дія предмет_структури_отримати_властивість(
    М: адреса<Машина>,
    предмет_структури: адреса<ПредметСтруктури>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      якщо предмет_структури.назва == пусто {
        вернути НЕДІЙСНЕ;
      }
      вернути ПРЕДМЕТ(предмет_структури.назва);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._параметри) {
      вернути ПРЕДМЕТ(предмет_структури.параметри);
    }

    змінна значення_властивості = НЕДІЙСНЕ;

    якщо знайти_призначене(
      М,
      предмет_структури.властивості,
      назва,
      значення_властивості::адреса
    ) {
      вернути значення_властивості;
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_Структура,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_структури_змінити_властивість(
    М: адреса<Машина>,
    предмет_структури: адреса<ПредметСтруктури>,
    назва: адреса<ПредметТексту>,
    значення: Значення,
    місцезнаходження: Місцезнаходження
  ) {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо змінити назву структури."), місцезнаходження);
      вернути;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._параметри) {
      МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо змінити параметри структури."), місцезнаходження);
      вернути;
    }

    змінити_властивість_структури(
      М,
      предмет_структури,
      назва,
      значення
    );
  }
}