// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  дія записати_метод_структури_ПеребірСловника__далі(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_ПеребірСловника(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(2);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._словник,
      пусто,
      пусто
    ));

    М.предмет_структури_ПеребірСловника.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_структуру_ПеребірСловника(
    М: адреса<Машина>
  ) {
    М.предмет_структури_ПеребірСловника.вбудована = так;
    М.предмет_структури_ПеребірСловника.заборонити_наслідування = так;

    записати_параметри_структури_ПеребірСловника(М);

    записати_метод_структури_ПеребірСловника__далі(М);
  }

  дія створити_перебір_словника(
    М: адреса<Машина>,
    предмет_словника: адреса<ПредметСловника>
  ) -> адреса<ПредметПереборуСловника> {
    змінна предмет = виділити_предмет<ПредметПереборуСловника>(М, М.предмет_структури_ПеребірСловника);

    предмет.предмет_словника = предмет_словника;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = НЕДІЙСНЕ;

    вернути предмет;
  }

  дія здійснити_структуру_перебору_словника(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити структуру \"ПеребірСловника\"."), місцезнаходження);
  }

  дія предмет_перебору_словника_отримати_властивість(
    М: адреса<Машина>,
    предмет_перебору_словника: адреса<ПредметПереборуСловника>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути предмет_перебору_словника.поточне_значення;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._словник) {
      вернути ПРЕДМЕТ(предмет_перебору_словника.предмет_словника);
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_ПеребірСловника,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}