// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  дія записати_метод_структури_ПеребірДаних__далі(М: адреса<Машина>);

  внутрішня дія записати_параметри_структури_ПеребірДаних(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(3);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._значення,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._дані,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._позиція,
      пусто,
      пусто
    ));

    М.предмет_структури_ПеребірДаних.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_структуру_ПеребірДаних(
    М: адреса<Машина>
  ) {
    М.предмет_структури_ПеребірДаних.вбудована = так;
    М.предмет_структури_ПеребірДаних.заборонити_наслідування = так;

    записати_параметри_структури_ПеребірДаних(М);

    записати_метод_структури_ПеребірДаних__далі(М);
  }

  дія створити_перебір_даних(
    М: адреса<Машина>,
    предмет_даних: адреса<ПредметДаних>
  ) -> адреса<ПредметПереборуДаних> {
    змінна предмет = виділити_предмет<ПредметПереборуДаних>(М, М.предмет_структури_ПеребірДаних);

    предмет.предмет_даних = предмет_даних;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = 0.0;

    вернути предмет;
  }

  дія здійснити_структуру_перебору_даних(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо здійснити структуру \"ПеребірДаних\"."), місцезнаходження);
  }

  дія предмет_перебору_даних_отримати_властивість(
    М: адреса<Машина>,
    предмет_перебору_даних: адреса<ПредметПереборуДаних>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> Значення {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      якщо предмет_перебору_даних.почато {
        вернути ЧИСЛО(р64(предмет_перебору_даних.поточне_значення));
      }
      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._дані) {
      вернути ПРЕДМЕТ(предмет_перебору_даних.предмет_даних);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._позиція) {
      якщо предмет_перебору_даних.почато {
        вернути ЧИСЛО(р64(предмет_перебору_даних.позиція));
      }
      вернути НЕДІЙСНЕ;
    }


    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_ПеребірДаних,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}