// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  внутрішня дія записати_параметри_структури_Параметр(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(3);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._назва,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._тип,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._дія_значення,
      пусто,
      пусто
    ));

    М.предмет_структури_Параметр.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_структуру_Параметр(
    М: адреса<Машина>
  ) {
    М.предмет_структури_Параметр.вбудована = так;
    М.предмет_структури_Параметр.заборонити_наслідування = так;

    записати_параметри_структури_Параметр(М);
  }

  дія створити_параметр(
    М: адреса<Машина>,
    назва: адреса<ПредметТексту>,
    тип: адреса<Предмет>,
    дія_значення: адреса<ПредметДії>
  ) -> адреса<ПредметПараметра> {
    змінна предмет = виділити_предмет<ПредметПараметра>(М, М.предмет_структури_Параметр);

    предмет.назва = назва;
    предмет.тип = пусто;
    предмет.дія_значення = дія_значення;

    вернути предмет;
  }

  дія здійснити_структуру_параметра(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо створити параметр вручну."), місцезнаходження);
  }

  дія предмет_параметра_отримати_властивість(
    М: адреса<Машина>,
    предмет_параметра: адреса<ПредметПараметра>,
    назва: адреса<ПредметТексту>, місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      вернути ПРЕДМЕТ(предмет_параметра.назва);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._тип) {
      якщо предмет_параметра.тип == пусто {
        вернути НЕДІЙСНЕ;
      }
      вернути ПРЕДМЕТ(предмет_параметра.тип);
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._дія_значення) {
      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_Параметр,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}