// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  внутрішня дія записати_параметри_структури_Дія(М: адреса<Машина>) {
    змінна кількість_параметрів = природне(4);
    змінна дані_параметрів = виділити<Значення>(М, кількість_параметрів);

    дані_параметрів[0] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._назва,
      пусто,
      пусто
    ));
    дані_параметрів[1] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._параметри,
      пусто,
      пусто
    ));
    дані_параметрів[2] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._тип_результату,
      пусто,
      пусто
    ));
    дані_параметрів[3] = ПРЕДМЕТ(створити_параметр(
      М,
      М.константи_назв._код,
      пусто,
      пусто
    ));

    М.предмет_структури_Дія.параметри = створити_послідовність_без_копіювання(
      М,
      кількість_параметрів,
      дані_параметрів
    );
  }

  дія заповнити_структуру_Дія(
    М: адреса<Машина>
  ) {
    М.предмет_структури_Дія.вбудована = так;
    М.предмет_структури_Дія.заборонити_наслідування = так;

    записати_параметри_структури_Дія(М);
  }

  дія створити_дію(
    М: адреса<Машина>,
    дійсність_створення: адреса<Дійсність>,
    назва: адреса<ПредметТексту>,
    параметри: адреса<ПредметПослідовності>,
    тип_результату: адреса<Предмет>,
    код: адреса<ПредметКоду>,
    шлях_до_теки_модулів: адреса<ПредметДаних>
  ) -> адреса<ПредметДії> {
    змінна предмет = виділити_предмет<ПредметДії>(М, М.предмет_структури_Дія);

    предмет.дійсність_створення = дійсність_створення;
    дійсність_створення.кількість_запозичень += 1;

    предмет.рідна = ні;
    предмет.назва = назва;
    предмет.параметри = параметри;
    предмет.код = код;
    предмет.тип_результату = тип_результату;
    предмет.шлях_до_теки_модулів = шлях_до_теки_модулів;
    предмет.метод_структури = пусто;

    вернути предмет;
  }

  дія створити_рідну_дію(
    М: адреса<Машина>,
    назва: адреса<ПредметТексту>,
    параметри: адреса<ПредметПослідовності>,
    тип_результату: адреса<Предмет>,
    рідна_дія: РіднаДія,
    шлях_до_теки_модулів: адреса<ПредметДаних>
  ) -> адреса<ПредметДії> {
    змінна предмет = виділити_предмет<ПредметДії>(М, М.предмет_структури_Дія);

    предмет.дійсність_створення = пусто;
    предмет.рідна = так;
    предмет.назва = назва;
    предмет.параметри = параметри;
    предмет.тип_результату = тип_результату;
    предмет.код = рідна_дія;
    предмет.шлях_до_теки_модулів = шлях_до_теки_модулів;
    предмет.метод_структури = пусто;

    вернути предмет;
  }

  дія здійснити_структуру_дії(
    М: адреса<Машина>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути МІСЦЕПАДІННЯ(М, створити_текст(М, "Неможливо створити дію вручну."), місцезнаходження);
  }

  дія предмет_дії_здійснити(
    М: адреса<Машина>,
    здійснювач: Значення,
    предмет_дії: адреса<ПредметДії>,
    задіяні: Задіяні,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо предмет_дії.рідна {
      змінна рідна_дія = предмет_дії.код як РіднаДія;

      змінна діяльність = покласти_в_історію_здійснення(
        М,
        пусто,
        здійснювач,
        предмет_дії,
        задіяні,
        місцезнаходження
      );

      змінна результат = рідна_дія(
        М,
        діяльність
      );

      якщо не М.стан_падіння {
        видалити_з_історії_здійснення(М, 1);
      }

      вернути результат;
    } інакше {
      змінна дійсність = створити_дійсність(
        М,
        предмет_дії.дійсність_створення
      );

      змінна діяльність = покласти_в_історію_здійснення(
        М,
        дійсність,
        здійснювач,
        предмет_дії,
        задіяні,
        місцезнаходження
      );

      якщо предмет_дії.параметри.розмір > 0 {
        змінна п: природне = 0;

        поки п < предмет_дії.параметри.розмір {
          змінна параметр = предмет_дії.параметри.елементи[п].дані як адреса<Предмет> як адреса<ПредметПараметра>;

          якщо (задіяні.розмір - задіяні.розмір_імен) > п {
            записати_в_дійсність(
              М,
              дійсність,
              параметр.назва,
              задіяні.дані[п]
            );
          } інакше {
            записати_в_дійсність(
              М,
              дійсність,
              параметр.назва,
              НЕДІЙСНЕ
            );
          }

          п += 1;
        }

        якщо задіяні.розмір_імен > 0 {
          п = 0;

          поки п < задіяні.розмір_імен {
            змінна назва = задіяні.дані_імен[п];
            змінна значення = задіяні.дані[задіяні.розмір - задіяні.розмір_імен + п];

            записати_в_дійсність(
              М,
              дійсність,
              назва,
              значення
            );

            п += 1;
          }
        }
      }

      змінна результат = виконати_код(
        М,
        М.накопичувач_значень::адреса,
        діяльність.спроби::адреса,
        дійсність,
        здійснювач,
        предмет_дії.код як адреса<ПредметКоду>,
        0,
        предмет_дії.шлях_до_теки_модулів
      );

      якщо М.стан_падіння {
        вернути НЕДІЙСНЕ;
      }

      видалити_з_історії_здійснення(М, 1);

      вернути результат;
    }
  }

  дія предмет_дії_отримати_властивість(
    М: адреса<Машина>,
    предмет_дії: адреса<ПредметДії>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._назва) {
      якщо предмет_дії.назва != пусто {
        вернути ПРЕДМЕТ(предмет_дії.назва);
      }

      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._параметри) {
      якщо предмет_дії.параметри != пусто {
        вернути ПРЕДМЕТ(предмет_дії.параметри);
      }

      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._тип_результату) {
      якщо предмет_дії.тип_результату != пусто {
        вернути ПРЕДМЕТ(предмет_дії.тип_результату);
      }

      вернути НЕДІЙСНЕ;
    }
    якщо перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._код) {
      якщо не предмет_дії.рідна {
        вернути ПРЕДМЕТ(предмет_дії.код як адреса<ПредметКоду>);
      }

      вернути НЕДІЙСНЕ;
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_Дія,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути ПРЕДМЕТ(предмет_методу);
  }
}