// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  дія записати_метод_структури_Послідовність__чародія_перебір(М: адреса<Машина>);

  дія заповнити_структуру_Послідовність(
    М: адреса<Машина>
  ) {
    М.предмет_структури_Послідовність.заборонити_наслідування = так;

    записати_метод_структури_Послідовність__чародія_перебір(М);
  }

  дія створити_послідовність(
    М: адреса<Машина>,
    розмір: природне,
    елементи: адреса<Значення>
  ) -> адреса<ПредметПослідовності> {
    змінна копія_елементів = виділити<Значення>(М, розмір);

    змінна п: природне = 0;
    поки п < розмір {
      копія_елементів[п] = елементи[п];
      п += 1;
    }

    змінна послідовність = виділити_предмет<ПредметПослідовності>(М, М.предмет_структури_Послідовність);

    послідовність.розмір = розмір;
    послідовність.елементи = копія_елементів;

    вернути послідовність;
  }

  дія створити_послідовність_без_копіювання(
    М: адреса<Машина>,
    розмір: природне,
    елементи: адреса<Значення>
  ) -> адреса<ПредметПослідовності> {
    змінна послідовність = виділити_предмет<ПредметПослідовності>(М, М.предмет_структури_Послідовність);

    послідовність.розмір = розмір;
    послідовність.елементи = елементи;

    вернути послідовність;
  }

  дія створити_сиру_послідовність(
    М: адреса<Машина>,
    розмір: природне
  ) -> адреса<ПредметПослідовності> {
    змінна послідовність = виділити_предмет<ПредметПослідовності>(М, М.предмет_структури_Послідовність);

    послідовність.розмір = розмір;
    послідовність.елементи = виділити<Значення>(М, розмір);

    вернути послідовність;
  }

  дія предмет_послідовності_отримати_властивість(
    М: адреса<Машина>,
    предмет_послідовності: адреса<ПредметПослідовності>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо назва == М.константи_назв._розмір або перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._розмір) {
      вернути ЧИСЛО(р64(предмет_послідовності.розмір));
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_Послідовність,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути МАШИННИЙ_ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_послідовності_отримати_елемент(
    М: адреса<Машина>,
    предмет_послідовності: адреса<ПредметПослідовності>,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    вернути НЕДІЙСНЕ;
  }
}