// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_метода_структури_ПеребірСловника__далі(
    М: адреса<Машина>,
    діяльність: адреса<Діяльність>
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗМашиннийПредмет і діяльність.здійснювач.вид != ЗСкладенийПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору словника \"далі\"."));
    }

    змінна предмет_перебору_словника = діяльність.здійснювач.дані як адреса<Предмет> як адреса<ПредметПереборуСловника>;

    якщо предмет_перебору_словника.тип != М.предмет_структури_ПеребірСловника {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору словника \"далі\"."));
    }

    якщо предмет_перебору_словника.почато {
      предмет_перебору_словника.позиція += 1;
    } інакше {
      предмет_перебору_словника.позиція = 0;
      предмет_перебору_словника.почато = так;
    }

    якщо предмет_перебору_словника.позиція < предмет_перебору_словника.предмет_словника.розмір {
      предмет_перебору_словника.поточне_значення = предмет_перебору_словника.предмет_словника.елементи[предмет_перебору_словника.позиція].ключ;

      вернути ДІЙСНЕ;
    }

    вернути НЕДІЙСНЕ;
  }

  дія записати_метод_структури_ПеребірСловника__далі(
    М: адреса<Машина>
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._далі,
      М.предмет_пустої_послідовності,
      пусто,
      рідна_дія_метода_структури_ПеребірСловника__далі,
      пусто
    );

    записати_метод_структури(
      М,
      М.предмет_структури_ПеребірСловника,
      М.константи_назв._далі,
      предмет_дії
    );
  }
}