// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  дія записати_метод_структури_ПеребірСловника__далі(М: адреса<Машина>);

  дія заповнити_структуру_ПеребірСловника(
    М: адреса<Машина>
  ) {
    М.предмет_структури_ПеребірСловника.заборонити_наслідування = так;

    записати_метод_структури_ПеребірСловника__далі(М);
  }

  дія створити_перебір_словника(
    М: адреса<Машина>,
    предмет_словника: адреса<ПредметСловника>
  ) -> адреса<ПредметПереборуСловника> {
    змінна предмет = виділити_предмет<ПредметПереборуСловника>(М, М.предмет_структури_ПеребірСловника);

    предмет.предмет_словника = предмет_словника;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = НЕДІЙСНЕ;

    вернути предмет;
  }

  дія предмет_перебору_словника_отримати_властивість(
    М: адреса<Машина>,
    предмет_перебору_словника: адреса<ПредметПереборуСловника>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо назва == М.константи_назв._значення або перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути предмет_перебору_словника.поточне_значення;
    }

    якщо назва == М.константи_назв._словник або перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._словник) {
      вернути МАШИННИЙ_ПРЕДМЕТ(предмет_перебору_словника.предмет_словника);
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_ПеребірСловника,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути МАШИННИЙ_ПРЕДМЕТ(предмет_методу);
  }
}