// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_метода_структури_ПеребірПослідовності__далі(
    М: адреса<Машина>,
    діяльність: адреса<Діяльність>
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗМашиннийПредмет і діяльність.здійснювач.вид != ЗСкладенийПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору послідовності \"далі\"."));
    }

    змінна предмет_перебору_послідовності = діяльність.здійснювач.дані як адреса<Предмет> як адреса<ПредметПереборуПослідовності>;

    якщо предмет_перебору_послідовності.тип != М.предмет_структури_ПеребірПослідовності {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору послідовності \"далі\"."));
    }

    якщо предмет_перебору_послідовності.почато {
      предмет_перебору_послідовності.позиція += 1;
    } інакше {
      предмет_перебору_послідовності.позиція = 0;
      предмет_перебору_послідовності.почато = так;
    }

    якщо предмет_перебору_послідовності.позиція < предмет_перебору_послідовності.предмет_послідовності.розмір {
      предмет_перебору_послідовності.поточне_значення = предмет_перебору_послідовності.предмет_послідовності.елементи[предмет_перебору_послідовності.позиція];

      вернути ДІЙСНЕ;
    }

    вернути НЕДІЙСНЕ;
  }

  дія записати_метод_структури_ПеребірПослідовності__далі(
    М: адреса<Машина>
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._далі,
      М.предмет_пустої_послідовності,
      пусто,
      рідна_дія_метода_структури_ПеребірПослідовності__далі,
      пусто
    );

    записати_метод_структури(
      М,
      М.предмет_структури_ПеребірПослідовності,
      М.константи_назв._далі,
      предмет_дії
    );
  }
}