// 2025-2026 Богданович Давид Когут Прихожденко (кдб.дійсність.укр)

взяти означення мавка/машина;

простір мавка {
  дія записати_метод_структури_ПеребірПослідовності__далі(М: адреса<Машина>);

  дія заповнити_структуру_ПеребірПослідовності(
    М: адреса<Машина>
  ) {
    М.предмет_структури_ПеребірПослідовності.заборонити_наслідування = так;

    записати_метод_структури_ПеребірПослідовності__далі(М);
  }

  дія створити_перебір_послідовності(
    М: адреса<Машина>,
    предмет_послідовності: адреса<ПредметПослідовності>
  ) -> адреса<ПредметПереборуПослідовності> {
    змінна предмет = виділити_предмет<ПредметПереборуПослідовності>(М, М.предмет_структури_ПеребірПослідовності);

    предмет.предмет_послідовності = предмет_послідовності;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = НЕДІЙСНЕ;

    вернути предмет;
  }

  дія предмет_перебору_послідовності_отримати_властивість(
    М: адреса<Машина>,
    предмет_перебору_послідовності: адреса<ПредметПереборуПослідовності>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо назва == М.константи_назв._значення або перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути предмет_перебору_послідовності.поточне_значення;
    }

    якщо назва == М.константи_назв._послідовність або перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._послідовність) {
      вернути МАШИННИЙ_ПРЕДМЕТ(предмет_перебору_послідовності.предмет_послідовності);
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_ПеребірПослідовності,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути МАШИННИЙ_ПРЕДМЕТ(предмет_методу);
  }
}