взяти означення мавка/машина;

простір мавка {
  дія записати_метод_структури_Словник__чародія_текст(М: адреса<Машина>);
  дія записати_метод_структури_Словник__чародія_перебір(М: адреса<Машина>);
  дія записати_метод_структури_Словник__ключі(М: адреса<Машина>);
  дія записати_метод_структури_Словник__значення(М: адреса<Машина>);
  дія записати_метод_структури_Словник__містить(М: адреса<Машина>);

  дія заповнити_структуру_Словник(
    М: адреса<Машина>
  ) {
    М.предмет_структури_Словник.заборонити_наслідування = так;

    записати_метод_структури_Словник__чародія_текст(М);
    записати_метод_структури_Словник__чародія_перебір(М);
    записати_метод_структури_Словник__ключі(М);
    записати_метод_структури_Словник__значення(М);
    записати_метод_структури_Словник__містить(М);
  }

  дія створити_словник(
    М: адреса<Машина>
  ) -> адреса<ПредметСловника> {
    змінна предмет = виділити_предмет<ПредметСловника>(М, М.предмет_структури_Словник);

    предмет.розмір = 0;
    предмет.елементи = пусто;

    вернути предмет;
  }

  дія записати_в_словник(
    М: адреса<Машина>,
    словник: адреса<ПредметСловника>,
    ключ: Значення,
    значення: Значення
  ) {
    змінна властивості_словника = словник;

    змінна п: природне = 0;

    поки п < властивості_словника.розмір {
      змінна елемент = властивості_словника.елементи[п]::адреса;

      якщо перевірити_чи_значення_рівні(М, елемент.ключ, ключ) {
        елемент.значення = значення;

        вернути;
      }

      п += 1;
    }

    властивості_словника.елементи = перевиділити_памʼять<ЕлементСловника>(М, властивості_словника.елементи, властивості_словника.розмір + 1);
    властивості_словника.елементи[властивості_словника.розмір] = ЕлементСловника { ключ, значення };
    властивості_словника.розмір += 1;
  }

  дія предмет_словника_отримати_властивість(
    М: адреса<Машина>,
    предмет_словника: адреса<ПредметСловника>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_Словник,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути МАШИННИЙ_ПРЕДМЕТ(предмет_методу);
  }

  дія предмет_словника_отримати_елемент(
    М: адреса<Машина>,
    предмет_словника: адреса<ПредметСловника>,
    ключ: Значення,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    змінна п: природне = 0;

    поки п < предмет_словника.розмір {
      змінна елемент = предмет_словника.елементи[п];

      якщо перевірити_чи_значення_рівні(М, елемент.ключ, ключ) {
        вернути елемент.значення;
      }

      п += 1;
    }

    вернути НЕДІЙСНЕ;
  }

  дія предмет_словника_змінити_елемент(
    М: адреса<Машина>,
    предмет_словника: адреса<ПредметСловника>,
    ключ: Значення,
    значення_елемента: Значення,
    місцезнаходження: Місцезнаходження
  ) -> СтанПадіння {
    змінна п: природне = 0;

    поки п < предмет_словника.розмір {
      змінна елемент = предмет_словника.елементи[п]::адреса;

      якщо перевірити_чи_значення_рівні(М, елемент.ключ, ключ) {
        елемент.значення = значення_елемента;

        вернути;
      }

      п += 1;
    }
  }
}